Alright, I have everything now except for one last thing.  Each part of this script now works all the way to selecting the user to log in automatically with and typing in the password.  Theres one last thing that I hope somebody can help me out with.  I kept testing the script from one part to the next, so I didn't catch this error until I ran it from the beginning.

What I did to get to the Login Options button was I did this

Applescript:

activate application "System Preferences"

tell application "System Events"
   tell process "System Preferences"
       application "System Preferences"
       
       keystroke (ASCII character of 31)
       delay 0.3
       keystroke (ASCII character of 31)
       delay 0.3
       keystroke (ASCII character of 31)
       delay 0.3
       keystroke (ASCII character of 31)
       delay 0.3
       keystroke (ASCII character of 31)
       delay 0.3
       keystroke (ASCII character of 31)
       delay 0.3
       keystroke (ASCII character of 31)
       delay 0.3
       keystroke (ASCII character of 31)
   end tell
end tell

I just added a bunch of down arrows to make sure it would go down the list no matter how long it is.  It all worked and went on to the next steps until I ran it from the beginning.
When you open System Preferences, the Search field in the top right of the window is highlighted, all keystrokes go in that box.  So now my downarrows do nothing.  Is there a way I can get that left side pane to be highligthed so the arrows will work there instead?

Thanks

hi jc,

i don't like doing system level stuff in GUI scripting, so i took a look to see how i'd add users from the command line.  i went ahead and worked up a script that works for me in 10.4 (*ONLY* tested in 10.4 Desktop) and the code is a lot shorter.  i'm sure there is a way to specify the user for 'Automatic Logon' but i have not found that yet.  (could it be a 'defaults' setting?).  anyway, here's the code, which you or somebody else might find useful:

Applescript:

-- createUser creates a user using the niutil command line utility
-- and uses Expect to create the password

-- these next few lines are the contents of a file we will create to set the password
property myExpect : "#!/usr/bin/expect
spawn passwd [lindex \\$argv 0]
set password [lindex \\$argv 1]
expect \"password:\"
send \"\\$password\\r\"
expect \"password:\"
send \"\\$password\\r\"
expect eof"

-- we get the highest user id in the 500 range, which we'll later increment and use for our new user
set getHighUID to (do shell script "/usr/bin/nireport / /users uid | /usr/bin/grep \"5[0-9][0-9]\"")
set howMany to number of words of getHighUID
set i to 1
set currWord to 0
set highWord to 0
repeat while i ≤ howMany
   set currWord to word i of getHighUID
   if currWord > highWord then
       set highWord to currWord
   end if
   set i to (i + 1)
end repeat

-- get the list of users so we can compare the new user and reject if they already exist
set getUsers to text of (do shell script "/usr/bin/nireport / /users name")

-- get the username and password (twice) as input from the user
set newUser to text returned of (display dialog "What is the name of the User you would like to add?" default answer "")
set userPass to text returned of (display dialog "What will be the password for this user?" default answer "" with hidden answer)
set userPassComp to text returned of (display dialog "Please reenter the password." default answer "" with hidden answer)

-- if the user already exists we need to error out. no need to be fancy.
-- if not, we will create the user, home directory & contents, plus the password.
if userPass is not userPassComp then
   display dialog "Those two passwords don't match. Please try again."
else
   if newUser is in getUsers then
       display dialog "That User already exists. Please try again."
   else
       do shell script "/usr/bin/niutil -create / /users/" & newUser with administrator privileges
       do shell script "/usr/bin/niutil -createprop / /users/" & newUser & " realname " & newUser with administrator privileges
       do shell script "/usr/bin/niutil -createprop / /users/" & newUser & " uid " & (highWord + 1) with administrator privileges
       do shell script "/usr/bin/niutil -createprop / /users/" & newUser & " home /Users/" & newUser with administrator privileges
       do shell script "/usr/sbin/createhomedir -u " & newUser with administrator privileges
       do shell script "/usr/bin/niutil -createprop / /users/" & newUser & " shell \"/bin/bash\"" with administrator privileges
       do shell script "/usr/bin/niutil -createprop / /users/" & newUser & " gid 20" with administrator privileges
       do shell script "/usr/bin/niutil -createprop / /users/" & newUser & " passwd \"*\"" with administrator privileges
       do shell script "/bin/cat > /tmp/expectPass << EOF
" & myExpect & "
EOF" with administrator privileges
       do shell script "/bin/chmod +x /tmp/expectPass" with administrator privileges
       do shell script "/tmp/expectPass " & newUser & space & userPass with administrator privileges
       display dialog "The new user " & newUser & " has been created."
       --if our Expect script exists, delete it.
       try
           do shell script "/bin/rm -rf /tmp/expectPass" with administrator privileges
       end try
   end if
end if

comments welcome.

EDITED:  to add an if statement.  then i changed it again.  and again.

Last edited by waltr (2006-07-18 05:24:19 pm)

I'd not really been following this topic, but thought I'd take a quick look at your script, jc - just in case you'd prefer to stick with the UI scripting approach.

While the following version may not yet do all you want, it does everything you described in your initial notes. It should certainly take you beyond the impasse over accessing the Login Options - and without a keystroke in sight. In fact, it completes the creation of a new user account and quits System Preferences, so any additional tweaks to the settings should now be a pretty straightforward matter. Hope it helps...

Applescript:

to authenticate_changes()
   tell application "System Events" to tell window "Authenticate" of process "SecurityAgent"
       tell group 1
           set value of text field 1 to "Administrator"
           set value of text field 2 to "myfakepassword"
       end tell
       click button "OK" of group 2
   end tell
end authenticate_changes

tell application "System Preferences"
   reveal anchor "passwordPref" of pane "Accounts"
   activate
end tell

tell application "System Events" to tell window "Accounts" of process "System Preferences"
   tell button "Click the lock to make changes." to if exists then
       click
       my authenticate_changes()
   end if
   click (first button whose name is "Button" and help is "Add a user account")
   
   tell sheet 1
       set value of text field 1 to "FRStudent"
       set value of text field 2 to "frstudent"
       set value of text field 3 to "frlab"
       set value of text field 4 to "frlab"
       click button "Create Account"
       repeat while exists
           delay 0.3
       end repeat
   end tell
   
   tell application "System Preferences" to reveal anchor "loginOptionsPref" of pane "Accounts"
   
   tell group 1
       click checkbox "Automatically log in as:"
       tell pop up button 1
           click
           click (first menu item of menu 1 whose name is "FRStudent")
       end tell
   end tell
   
   tell sheet 1
       repeat until exists
           delay 0.2
       end repeat
       set value of text field 1 to "frlab"
       click button "OK"
   end tell
   click button "Click the lock to prevent further changes."
end tell

quit application "System Preferences"

Last edited by kai (2006-07-20 03:31:06 am)

Hi Rowie

This Works but please treat it like the blunt instrument it is. a few other factors could come into place
and usually do when UI scripting.
this selects the next user in the list

Applescript:

tell application "System Preferences"
   reveal anchor "passwordPref" of pane "Accounts"
   activate
end tell
tell application "System Events"
   tell process "System Preferences"
       tell window "Accounts"
           keystroke tab
           keystroke (ASCII character of 31)
       end tell
   end tell
end tell

Hi Rowie

Sorry this didn't work for you. like i said blunt instrument.
It's probably just the way are machines are set up i guess (i'm on 10.4.8 as well) and it works on mine
Is your padlock locked or unlocked this may make a difference it might be an idea to add the unlock bit
into this script..
if i get chance i'll look further into this, i'm sure someone else with a bit more experience will no how
to solve this for you.
does this have a better result:

Applescript:

tell application "System Preferences"
   reveal anchor "passwordPref" of pane "Accounts"
   activate
end tell

tell application "System Events" to tell window "Accounts" of process "System Preferences"
   tell button "Click the lock to make changes." to if exists then
       click
       my authenticate_changes()
   end if
   delay 4
   keystroke tab
   keystroke (ASCII character of 31)
end tell

to authenticate_changes()
   tell application "System Events" to tell window "Authenticate" of process "SecurityAgent"
       tell group 1
           set value of text field 1 to "Administrator"
           set value of text field 2 to "yourpassword"
       end tell
       click button "OK" of group 2
   end tell
end authenticate_changes

good luck

Last edited by pidge1 (2006-12-24 04:57:17 am)

Hi rowie


system prefs version 3.5
running on intel macbook pro!
maybe there lies the answer!
will test it on a power pc when i get chance...

sorry rowie just reading your last post again.
The tab for me just highlights the list of users the ascii keystroke 31 which is the down arrow skips to the second user
in the list.

Last edited by pidge1 (2006-12-24 12:27:00 pm)

StefanK wrote:

Hi,

UI scripting is very sensitive with different localizations.
I tried to change the script to an language independent version.
On my Dual G5 with german 10.4.8 system this works:

Applescript:

tell application "System Preferences"
   reveal anchor "passwordPref" of pane id "com.apple.preferences.users"
   activate
end tell

tell application "System Events" to tell window 1 of process "System Preferences"
   tell button 4 to if exists then
       click
       my authenticate_changes()
   end if
   delay 4
   keystroke tab
   keystroke (ASCII character of 31)
end tell

to authenticate_changes()
   tell application "System Events" to tell window 1 of process "SecurityAgent"
       tell group 1
           set value of text field 1 to "Administrator"
           set value of text field 2 to "yourpassword"
       end tell
       click button "OK" of group 2
   end tell
end authenticate_changes

Thanks for the attempt Stefan, but this doesnt work. In this script, and the previously discussed ones, the tab key is being used to set the focus on the users list and then the down arrow to select the second user. The issue here appears to be that on the computers I am working with, the tab key does not activate or set the focus on the users list. Without even using Applecript, just manually attempting to use the tab key to set the focus on the users list in the Sys Prefs, it just doesnt work. The focus toggles between the search field at the top right and the fields within the various panes, but never sets the focus on the users list. I am using Power PC machines with OS 10.4.8 and System Preferences 3.3.

I thought maybe the difference in systems between myself and Pidge might have explained why it doesnt work for me, but Stefan, you said you are using a PPC mac with 10.4.8, so now Im really baffled. What version of Sys Prefs do you have Stefan?

Ah, Stefan, you are truly my hero. I have to admit I feel a bit silly not ever having seen that option, but I guess I never had a use for it before. My sincerest thanks for bringing it to my attention...problem solved! 

Works for me Nigel.

Thanks, guys.

Hey guys,

I got a Kai's script working great.  I'm trying to create an Admin account and can't figure out how to select the check box "allow user to administer the computer"  I know it's something as simple as setting the value of the Checkbox to 1 (1 for checked, 0 for unchecked).  I think I just need some help with the syntax

tell application "System Events"
    tell process "System Preferences"
        application "System Preferences"
        tell sheet 1 of window "Accounts"
            set value of text field 1 to "Local Admin"
            -- Display Name
            set value of text field 2 to "LocalAdmin"
            -- Short Name
            set value of text field 3 to "*****"
            -- Password
            set value of text field 4 to "*****"
            -- Verify Password
            set value of text field 5 to "default local admin pwd"
            -- Add's Comment for password hint field
            set value of checkbox 1 to 1

            click button "Create Account"
        end tell
    end tell
end tell

Any ideas?

Thanks,

Jeff

P.S.  Sorry for being a N00B

Model: Tiger 10.4.6
AppleScript: 2.11 (81)
Operating System: Mac OS X (10.4)

Never mind... Setting the checkbox value to 1 worked