Mikey,
Thanks for that clarification on NSScreen - as it can return resolution of all screens, I think it will be my method of choice in AS applications. Now, if only I could find a universal method for simple Applescript...
As an aside, I now realise why Method1 (NSDisplaysDataType) doesn't work on System 2: System Profiler doesn't have a supported data type by this name! Opening up System Profiler, display resolution appears to be buried in a series of submenus:
Hardware -> PCI/AGP Cards -> ATY,RV360M11 -> Display
I can access the PCI profile with

Applescript:

do shell script "system_profiler SPPCIDataType"

but this only returns
"PCI/AGP Cards:

    TXN,PCIXXXX-00:
   
      Name: cardbus
      Type: cardbus
      Bus: PCI
      Slot: PC Card
      Vendor ID: 0x104c
      Device ID: 0xac56
      Revision ID: 0x0000
   
    ATY,RV360M11:
   
      Type: display
      Bus: AGP
      VRAM (Total): 64 MB
      Vendor: ATI (0x1002)
      Device ID: 0x4e50
      Revision ID: 0x0000
      ROM Revision: 113-xxxxx-134
   
        ATY,Jasper_A:
       
          Type: display
          Display Type: LCD
          VRAM (In Use): 64 MB
       
        ATY,Jasper_B:
       
          Status: No display connected"

Does anyone have any ideas how to access display resolution with system_profiler in this instance?
Thanks,
PJ.

Model: Powerbook G4
Browser: Safari 417.8
Operating System: Mac OS X (10.3.9)

Ok, the original post a quite old, but here are two additional approaches:

First:

Applescript:

set disWidth to word 1 of (do shell script "defaults read /Library/Preferences/com.apple.windowserver DisplaySets | grep Width | cut -f 2 -d '=' | cut -f 1 -d ';'") as integer
set disHeight to word 1 of (do shell script "defaults read /Library/Preferences/com.apple.windowserver DisplaySets | grep Height | cut -f 2 -d '=' | cut -f 1 -d ';'") as integer

Second: install the little command line cscreen in /usr/bin

Here is a subroutine to get the parameters of all connected displays or of one specified display:

Applescript:

set {maxDisplay, disParam} to cscreen(0) -- 0 = all displays, >0 = specified display

on cscreen(display)
   try
       ((path to startup disk as string) & "usr:bin:cscreen") as alias
   on error
       return {false, false}
   end try
   set disParam to words of (do shell script "cscreen -l")
   set maxDisplay to item 1 of disParam as integer
   if display = 0 then
       set dispList to {}
       repeat with i from 1 to maxDisplay
           copy get_param(i, disParam) to end of dispList
       end repeat
       return {maxDisplay, dispList} -- list of max. number of displays and record(s) of parameters
   else if display is less than or equal to maxDisplay then
       return {maxDisplay, get_param(display, disParam)}
   else
       return {false, false}
   end if
end cscreen

on get_param(DIndex, d)
   set i to 14 + ((DIndex - 1) * 5)
   set DisRecord to {DNum:item i of d, DDepth:item (i + 1) of d, DWidth:item (i + 2) of d, DHeight:item (i + 3) of d, DFreq:item (i + 4) of d}
   if DFreq of DisRecord = "0" then set DFreq of DisRecord to "TFT"
   return DisRecord
end get_param

both solutions work on Panther and Tiger

Last edited by StefanK (2006-12-28 05:01:30 pm)

Thanks, Adam, I changed the link in my post above

Hi, Jacques.

Thanks! Those both work on both systems and are more compact than – and nearly twice as fast as – my effort. The 'grep' version may possibly be very slightly faster than the 'awk', but it's too close a call to be sure. They're still several times slower than Jon’s Commands, but since that's apparently not going to be ported for Intel machines, I'm keeping an eye on the alternatives!

Applescript:

set screenRes to screen size of beginning of (screen list starting with main screen) -- Needs Jon’s Commands.

Adam Bell wrote:

Elegant as these solutions are, I still have to use cscreen because I have two screens.

No problem, Adam, this returns the values for two screens ({x1, y1, x2, y2})

Applescript:

tell (do shell script "defaults read /Library/Preferences/com.apple.windowserver DisplaySets | awk '/ Height =/||/ Width =/'") to set screenRes to {word 6 as integer, word 3 as integer, word 12 as integer, word 9 as integer}

I see that the very first key in the "com.apple.windowserver" domain is "CGSInterocitorSelectMode". An interocitor, of course, is an alien device from the 1954 Sci-Fi film This Island Earth. There are quite a few people having fun with it on the Net. I quite enjoyed this effort. (Follow the "About this page" link for more information.) 

Adam Bell wrote:

Elegant as these solutions are, I still have to use cscreen because I have two screens.

I saw Stefan's solution, but does this work?:

Applescript:

(do shell script "defaults read /Library/Preferences/com.apple.windowserver DisplaySets | sed -Ee '/^ *(Height|Width)/!d' -e 's/[^[:digit:]]*//g'")'s paragraphs

Qwerty Denzel wrote:

I saw Stefan's solution, but does this work?:

Applescript:

(do shell script "defaults read /Library/Preferences/com.apple.windowserver DisplaySets | sed -Ee '/^ *(Height|Width)/!d' -e 's/[^[:digit:]]*//g'")'s paragraphs

Hi, Qwerty.

It errors in Jaguar ("Illegal operation") but returns a list of numeric Unicode texts in Tiger. For a single screen, we'd need something like this:

Applescript:

tell (do shell script "defaults read /Library/Preferences/com.apple.windowserver DisplaySets | sed -Ee '/^ *(Height|Width)/!d' -e 's/[^[:digit:]]*//g'") to set screenRes to {paragraph 2 as integer, paragraph 1 as integer}

Adam Bell wrote:

Nigel Garvey wrote:

Adam Bell wrote:

When I read the link you gave and look back at CGSInterocitor's value, mine is an integer set to zero. Is that universal or does it vary from country to country? If the latter, then it's a quite suitable name for identifying "aliens" presuming the "0" means USA.

No. It's "0" here too – and we're not aliens. 

Apparently Canadians aren't either (I'm happy to say)

Interestingly enough, after posting that, I tried changing the value to "1" to see what would happen and actually turned into an alien for a while. Fortunately, I was able to slither into a vat of dinitrogen tetrasulphide while I restored the backup and, after a good night's sleep and a cup of tea, am apparently no worse off for the experience. But thank goodness I didn't try the "2" setting!

After fiddling around for a short while, I've finally settled on this. It should hopefully return a list of records, but unfortunately I'm unable to test it on more than one display.

Applescript:

run script ("{" & (do shell script "defaults read /Library/Preferences/com.apple.windowserver DisplaySets | sed -Ee '/^ *(Height|Width)/!d' -e 's/Height = (.*);/{height: \\1,/' -e 's/Width = (.*);/width: \\1},/' -e 's/ *$/¬/'")'s text 1 thru -3 & "}")

I presume that, as the last one died of an obscure error, this too will fail on Jaguar.

Edit: Thanks Stefan, my fault. The script has been changed.

Last edited by Qwerty Denzel (2007-01-02 04:09:59 am)

FWIW, Extra Suites may come in handy when changing screenresolutions AND depth on a fly (here for single screen):

Applescript:

tell application "Extra Suites" to set g to ES list screen resolutions screen 0

set y to {}
repeat with x in g
   if x is g's last item as string then set x to " depth " & x
   set y to y & my substitute(x, "x", "*")
end repeat
tell application "System Events" to set fApp to some application process whose frontmost is true
beep 2
tell fApp
   activate
   set fWd to name of window 1
   set fWd2 to name of front window
   set nRes to (choose from list y default items {item 3 of y} with prompt "Set screen resolution to: ")
end tell
if nRes = false then return
set nRes to nRes as string
set {nH, nV, dept} to {nRes's word 1, nRes's word 3, nRes's word 5} --return {nH, nV}

tell application "Extra Suites"
   set sInfo to ES screen info
   if width of sInfo ≠ nH and height of sInfo ≠ nV then
       ES set screen resolution width nH height nV depth dept
   end if
   set sInfo to ES screen info
   set {W, H} to {sInfo's width, sInfo's height}
end tell

tell fApp
   activate
   try
       open window 1
   end try
   try
       open window fWd
   end try
   try
       open window fWd2
   end try
   return name of window 1
end tell

on substitute(theText, toReplace, newText)
   set AppleScript's text item delimiters to the toReplace
   set the allTheText to every text item of theText
   set AppleScript's text item delimiters to the newText
   set theText to the allTheText as string
   set AppleScript's text item delimiters to ""
   return theText
end substitute

Last edited by Eelco Houwink (2007-01-02 04:04:56 am)

Qwerty Denzel wrote:

Stefan, I've updated the script, so hopefully it now works for you.

yes, it works perfectly now with two displays