Have you looked at Advanced Filter's Unique only option?

When you say "duplicate rows" does that mean that each cell in the row is to be checked?
i.e.

Smith 1
Jones 2
Smith 3

is that OK
or
should one of the Smith's go, if so which Smith?

OR (he hopes. he hopes) is there a column where a duplicate in that column implies that the other columns are the same. i.e. two Smiths implies that the number is the same and it doesn't matter which row gets deleted?

To use Advanced Filter, each column has to have a unique header and there can be no blank rows.
This will copy myMessyRange to myCleanRange without duplicates. The optional last line deletes myMessyRange, leaving the un-duplicated data.

Applescript:

tell application "Microsoft Excel"
   set myMessySheet to get worksheet "Sheet1" of workbook "Workbook2.xls"
   set myMessyRange to get current region of range "A1" of myMessySheet
   
   set myCleanRange to get resize (get offset (myMessyRange) column offset ((count of columns of myMessyRange) + 1)) row size 1
   
   advanced filter myMessyRange action filter copy copy to range myCleanRange with unique
   
   -- optional deletes dirty range
   delete range (entire column of (get resize myMessyRange column size ((count of columns of myMessyRange) + 1))) shift shift to left
end tell

This will insert a header row, fill it with unique headers and delete after Filter has done its work.

Applescript:

tell application "Microsoft Excel"
   set myMessySheet to get worksheet "Sheet1" of workbook "Workbook1.xls"
   set myMessyRange to get current region of range "A1" of myMessySheet
   
   insert into range (entire row of (row 1 of myMessyRange)) shift shift down
   
   set headerRow to get resize (row 1 of myMessyRange) row size 1 column size (count of columns of myMessyRange)
   
   set formula of headerRow to "=\"header\"&column()"
   set value of headerRow to get value of headerRow
   
   set myCleanRange to get resize (get offset (myMessyRange) column offset ((count of columns of myMessyRange) + 1)) row size 1
   
   advanced filter myMessyRange action filter copy copy to range myCleanRange with unique
   delete range (entire row of headerRow) shift shift up
   -- optional deletes dirty range
   delete range (entire column of (get resize myMessyRange column size ((count of columns of myMessyRange) + 1))) shift shift to left
end tell

Mike,

I've tried to implement this script as part of a subroutine in my application. I have a popup button where if the user selects xls files to merge, a checkbox button "duplicate" becomes visible and the default is unchecked (0 state).  During the merge of the xls files,  if the state of the "duplicate" is 1, I need to run the delete duplicate rows subroutine deleteRows. 

Applescript:

tell application "Microsoft Excel"
       
       open text file filename output_ data type delimited text qualifier text qualifier double quote with comma
       set display alerts to false
       save active workbook in output_ as default save format
       if state of button "duplicate" of window "merger" is 1 then
           deleteRows()
       end if
       
       quit

Applescript:

on deleteRows()

set myMessyRange to get current region of range "A1"
   insert into range (entire row of (row 1 of myMessyRange)) shift shift down
   set headerRow to get resize (row 1 of myMessyRange) row size 1 column size (count of columns of myMessyRange)
   
   set formula of headerRow to "=\"header\"&column()"
   set value of headerRow to get value of headerRow
   
   set myCleanRange to get resize (get offset (myMessyRange) column offset ((count of columns of myMessyRange) + 1)) row size 1
   
   advanced filter myMessyRange action filter copy copy to range myCleanRange with unique
   delete range (entire row of headerRow) shift shift up
   -- optional deletes dirty range
   delete range (entire column of (get resize myMessyRange column size ((count of columns of myMessyRange) + 1))) shift shift to left
end deleteRows

I am not certain the subroutine can be called in the middle of the script where it needs to look at the state of a button on a separate window.  I get a syntax error where "region" is highlighted in the deleteRows sub.  Your thoughts...

Although the subroutine was being called from within the Tell block of Excel application, I still need to indicate the Tell block for deleteRows()?  Yep, that worked...now, the code is being hung up on this section where the state of button is being checked:

Applescript:

...
tell application "Microsoft Excel"
       
       open text file filename output_ data type delimited text qualifier text qualifier double quote with comma
       set display alerts to false
       save active workbook in output_ as default save format
       if state of button "duplicate" of window "merger" is 1 then
           my deleteRows() *******hung up here*************
       end if
       if state of button "duplicate" of window "merger" is 0 then
           quit
       end if
       
   end tell

Am I setting the button correctly?  This is driving me nuts!  Thanks for all your help (as a sidebar, Stefan also pointed out the issue with the missing tell block)

The checkbox is on the main NSWindow "merger" (the UI).

SOLVED!

My if-else syntax was incorrect. All's well and thanks Mike.