Hi,

The main error is the file you're saving into. By AppleWorks dictionary, you want a file to save to and not a folder. You used the path to the desktop as the path to your file.

property theTranslator : "Word Windows 97, 2000, XP 2002 "
property desktopPath : path to desktop as text

set file_spec to (desktopPath & "MyWord.doc") as file specification -- made a file specification
set currentFile to choose file
tell application "Finder"
    if kind of currentFile is not folder then
        if file type of currentFile is "CWWP" then
            -- set currentPath to currentFile as text -- AW6 wants a path, not an alias -- alias ref is ok
            try
                set theCounter to 0 -- initialized variable theCounter
                tell application "AppleWorks 6"
                    activate
                    open currentFile -- alias reference is ok
                    save front document in file_spec using translator theTranslator -- fixed the reference
                    close front document without saving
                    set theCounter to theCounter + 1
                end tell
            on error theError
                display dialog theError
            end try
        end if
    end if
end tell

A fiile specification is a reference to a file that may not already exist.

gl,

You're welcome. Glad it worked for you.

gl,

Heylo Tom,

After spending many days working on a similar project I finally stumbled across your script.  I took the liberty of rewriting several sections to fit my needs.  If time permits I will go back through and add the wonderful comments/explanations you had in your script.  But thought I would share my changes.  I didn't set mine up as a droplet, but I think that could be easily modified. I learned a lot while writing this and will definitely spend more time visiting this forum.

Thanks and Have A Great Day.

Rick Davis

Applescript:

-- Original code written by:
-- AW6 to MS Word Converter
-- By Tom McKenna
-- May 23, 2004

property theSprTranslator : "Excel Win 97, 2000, XP 2002 spr"
property theTranslator : "Word Windows 97, 2000, XP 2002 "

on run
   
   
   tell application "Finder"
       activate
       set theFiles to choose folder
       
       if exists (folder "Converted Word Docs" of theFiles) then
           
           display dialog "There is already a Converted Word Docs folder. Please move this folder to another location and try again." buttons {"Cancel"} default button 1 with icon note
           error number -128
           
           return
           
       else
           
           make new folder at theFiles with properties {name:"Converted Word Docs"}
           select (items of theFiles whose kind is not "folder" and file type is "CWWP")
           
           copy selection to folder "Converted Word Docs" of theFiles
           
       end if
       
   end tell
   
   try
       tell application "Finder"
           activate
           set newFiles to folder "Converted Word Docs" of theFiles
           
           repeat with newFile in newFiles
               
               if kind of newFile is not equal to "Folder" then
                   set FileName to (name of newFile) as text
                   set Filenamelength to length of FileName
                   set Suffix to ".doc"
                   if file type of newFile is "CWWP" then
                       -- set currentPath to currentFile as text -- AW6 wants a path, not an alias -- alias ref is ok
                       if FileName ends with ".cwk" then
                           
                           set nameCount to count of characters in FileName
                           set FileName to ¬
                               (characters 1 through (nameCount - 4) of FileName as string)
                       end if
                       
                       if Filenamelength > 27 then
                           
                           set TopLimit to (Filenamelength + (27 - Filenamelength))
                           
                           copy characters 1 through TopLimit of FileName as string to NewFilename
                           
                           set NewFilename to NewFilename & Suffix
                           
                       else
                           
                           set NewFilename to FileName & Suffix
                           
                       end if
                       
                       try
                           set the name of newFile to NewFilename
                       on error
                           set name of newFile to the text returned of (display dialog "Truncating this file name will create a duplicate file name, which will cause an error and halt the process. Please rename this file to a unique name. If the file name you enter here is already in use the operation will end and you will need to check for any files not converted and try again." default answer NewFilename)
                           
                       end try
                   end if
                   
                   
                   
                   
                   try
                       
                       tell application "AppleWorks 6"
                           activate
                           open newFile -- alias reference is ok
                           
                           save using translator theTranslator with NewFilename and replace
                           close front document without saving
                           
                       end tell
                   on error theError
                       display dialog theError
                   end try
               else
                   (display dialog "This is not an Appleworks document and will not be converted")
                   
                   
               end if
               tell application "Finder"
                   set the file type of newFile to "W8BN"
                   set the creator type of newFile to "MSWD"
                   
               end tell
               
           end repeat
           
       end tell
   end try
   
   tell application "Finder"
       
       if exists (folder "Converted Spreadsheets" of theFiles) then
           
           display dialog "There is already a Converted Spreadsheets folder. Please move this folder to another location and try again." buttons {"Cancel"} default button 1 with icon note
           error number -128
           
           return
           
       else
           
           make new folder at theFiles with properties {name:"Converted Spreadsheets"}
           select (items of theFiles whose kind is not "folder" and file type is "CWSS")
           
           copy selection to folder "Converted Spreadsheets" of theFiles
           
       end if
       
   end tell
   
   
   
   try
       tell application "Finder"
           activate
           set newsprFiles to folder "Converted Spreadsheets" of theFiles
           
           repeat with newsprFile in newsprFiles
               
               if kind of newsprFile is not equal to "Folder" then
                   set FileName to (name of newsprFile) as text
                   set Filenamelength to length of FileName
                   set Suffix to ".xls"
                   if file type of newsprFile is "CWSS" then
                       -- set currentPath to currentFile as text -- AW6 wants a path, not an alias -- alias ref is ok
                       if FileName ends with ".cwk" then
                           
                           set nameCount to count of characters in FileName
                           set FileName to ¬
                               (characters 1 through (nameCount - 4) of FileName as string)
                       end if
                       
                       if Filenamelength > 27 then
                           
                           set TopLimit to (Filenamelength + (27 - Filenamelength))
                           
                           copy characters 1 through TopLimit of FileName as string to NewFilename
                           
                           set NewFilename to NewFilename & Suffix
                           
                       else
                           
                           set NewFilename to FileName & Suffix
                           
                       end if
                       
                       try
                           set the name of newsprFile to NewFilename
                       on error
                           
                           set name of newsprFile to the text returned of (display dialog "Truncating this file name will create a duplicate file name, which will cause an error and halt the process. Please rename this file to a unique name. If the file name you enter here is already in use the operation will end and you will need to check for any files not converted and try again." default answer NewFilename)
                           tell application "Finder"
                               activate
                           end tell
                           
                       end try
                   end if
                   
                   
                   
                   
                   try
                       
                       tell application "AppleWorks 6"
                           activate
                           open newsprFile -- alias reference is ok
                           
                           save using translator theSprTranslator with NewFilename and replace
                           close front document without saving
                           
                       end tell
                   on error theError
                       display dialog theError
                   end try
               else
                   tell current application
                       activate
                       (display dialog "This is not an Appleworks document and will not be converted")
                   end tell
                   
               end if
               tell application "Finder"
                   set the file type of newsprFile to "XLS8"
                   set the creator type of newsprFile to "XCEL"
                   
               end tell
               
           end repeat
           
       end tell
   end try
   
   
   
   
   tell current application
       activate
       display dialog "Congratulations! Your files have been converted from AppleWorks 6 format to Microsoft Word and Excel for Windoze format." buttons {"OK"} default button 1
       
   end tell
end run

Hi tmckenna,

Your script looks pretty good to me.

Here's a few things you might try:

When you get some text from a string, instead of getting 'characters' use text. For example:

set the_string to "somefilename.ext"
set dot_offset to (offset of "." in the_string) - 1
set the_name to (text 1 thru dot_offset of the_string)

When you use 'charaters of ...', you get a list of characters and then you need to coerce to string. This way you just get a range of text.

Try to avoid nested tell blocks and using scripting addition commands in application tell blocks if possible. Firstly, you might get conflicts with key words. Another, if your wording is not exact for an inner tell block, the script will look for the next target and might use the dictionary of the outer tell block. So, your syntax check might come out ok but it won't work as expected. For instance, after a quick glance at your script, it looks like you can do the 'info for' command outside the Finder tell block and the AppleWorks tell block looks like it doesn't need to be inside the Finder tell block. Doing this may increase speed also, as the Finder is not needed there anyway.

Edit: I just looked through the script again and found that the Finder is not needed in the repeat loop. The 'info for' command returns a record with a lot of information.

Edit: more stuff. 'path to dektop' is used more than once. I like to put this in a variable. It helps to not crunch statements also for debugging especially when starting off. This section:

tell application "Finder"
    make new folder at desktop with properties {name:"Converted Items"}
    set targetFolder to ((path to desktop folder as text) & "Converted Items:") as text
end tell

In OSX, Finder 'make' command returns a reference to the item. So, the second line is not needed.

tell application "Finder"
    set targetFolder to (make new folder at desktop with properties {name:"Converted Items"}) -- as text -- if a reference is not needed later
end tell

If you're using a reference to the made folder later, then coerce to alias (as alias). This is good if you're using the reference out of the Finder as the Finder returns a Finder reference.

Good Job,

well, the hackish way i can think of fixing that is doing this:

find the part of the script where it says

-- Step Four B: Check to see if the file has a .cwk extension and if need be, remove it
   if currentName ends with ".cwk" then
      set nameCount to count of characters in currentName
      set currentName to ¬
        (characters 1 through (nameCount - 4) of currentName as string)
end if

add this below that line:

-- Step Four B Part Two: Check to see if the file has a .cwk extension and if need be, remove it
   if currentName ends with ".CWK" then
      set nameCount to count of characters in currentName
      set currentName to ¬
        (characters 1 through (nameCount - 4) of currentName as string)
end if

i'm pretty sure there is a better way to do that, but i think that will do it just fine.  i wish i could test it, but i don't have appleworks on this comp.

well, maybe it has something to do with the file type then, which would take effect in this line:

Applescript:

 if file type of currentFile is "CWWP" then.....

that part of the code is making sure that it is an applescript file.  as long as you are SURE that they are all applescript files, you can just get rid of that part of code:  delete the  " if file type of currentFile is "CWWP" then "  and also delete the 'end if' that is here:

on error theError
                         display dialog theError
                    end try
               end if
          end tell

Hello--

I am glad that the script is helping people!

As for designbysue's problems, the only thing I can think of (without being able to see the files that were causing the problem) is that the file type in older versions of AppleWorks is different. Until I see one of the problem files, I can't really fix the problem.

Anyway, since everyone is using the script -- let me post the latest cleaned up version of the script.

I hope it helps someone!

--Tom

(* AW6 to MS Word Converter
By Tom McKenna
May 23, 2004, Last revised August 3, 2004

This droplet converts AppleWorks word processing documents that are dropped on it
into Microsoft Word documents.
Revisions:
     With the help of others, re-wrote DestinationFolder(). It's much better now.
     Condensed code, where possible
     Decided to implement handlers as an exercise in better script writing *)

property theTranslator : "Word Windows 97, 2000, XP 2002 "
property theExtension : ".doc"
property desktopPath : (path to desktop as Unicode text)
global targetFolder
global theCounter

on VersionCheck()
     tell application "AppleWorks 6"
          if (its version as string) is not "6.2.9" then display dialog "Go to http://www.apple.com/appleworks and download the latest version of AppleWorks 6 and then re-run this script." buttons {"Cancel"}
     end tell
end VersionCheck

on DestinationFolder()
     try
          tell application "Finder" to set targetFolder to (make new folder at desktop with properties {name:"Converted Items"}) as text
     on error -- The folder already exists...
          display dialog "A Converted Items folder already exists on the desktop. Do you want to continue?" buttons {"Cancel", "OK"} default button 2
          set targetFolder to (desktopPath & "Converted Items:") as text
     end try
end DestinationFolder

on ConvertLoop(droppedFiles)
     tell application "Finder" to repeat with currentFile in droppedFiles
          if file type of currentFile is "CWWP" then
               set currentName to the name of currentFile
               if currentName ends with ".cwk" then
                    set chopExt to (offset of "." in currentName) - 1
                    set currentName to (text 1 thru chopExt of currentName)
               end if
               try
                    tell application "AppleWorks 6"
                         open file (currentFile as Unicode text)
                         save front document in file ((targetFolder & currentName & theExtension) as string) using translator theTranslator
                         close front document without saving
                    end tell
                    set theCounter to theCounter + 1
               on error theError
                    display dialog theError
               end try
          end if
     end repeat
end ConvertLoop

on CleanupThings()
     tell application "AppleWorks 6" to quit
     display dialog "Congratulations! " & (theCounter as string) & " file(s) have been converted from AppleWorks 6 file format to Microsoft Word file format." buttons {"OK"} default button 1
end CleanupThings

on open droppedFiles
     VersionCheck()
     DestinationFolder()
     set theCounter to 0
     ConvertLoop(droppedFiles)
     CleanupThings()
end open

-------------------------
[This script was automatically tagged for color coded syntax by Convert Script to Markup Code]

Hi tmckenna,

If you learn from your mistakes, then persistence is good. It's like you're evolving! :-)

You may write global variables on one line separated by commas. For example:

global theCounter, targetFolder

It's good practice to make subroutines modular. You could make your TranslatorCheck() subroutine modular by passing it the translator. Also, try not to jump with 'return'. This makes scripts harder to read.

on TranslatorCheck(theTranslator) -- Makes sure that the necessary translator is installed
      tell application "AppleWorks 6" to set translatorList to export translators
      if theTranslator is not in translatorList then
      tell application "AppleWorks 6" to quit
     display dialog "You need to update to the latest version of AppleWorks 6 to ensure that you have the proper file translators installed." buttons {"Cancel"} default button "Cancel"
      -- tell application "AppleWorks 6" to quit -- these lines are not necessary
      -- error number -128 -- the Cancel button causes an error
      -- place a 'return xxx' at the end of subroutines
      end if
      return true
end TranslatorCheck

Whew, just this starting section took me about an hour. I love to teach though. Need  to do something right now. Will continue.

Later,