Finder Open Window At Location in Column View

Hi folks.

So I want to do just that, but let me break it down:

  • open a window with (x,y) origin (this is a location on my multiple-monitor real-estate), with window dimensions. I can do this already, I’ll post below.
  • I want this window to park itself at a certain location (this is a SAN directory)

Here’s the first part:

tell application "Finder"
	open targetFolder
	set w1 to make new Finder window
	tell w1
		set the current view to column view
	end tell
	activate
end tell

Can this be done?

Hi
If i’m understanding this correctly, something like this maybe, I have three monitors to move things around on and this works well.

tell application "Finder"
	set folder_name to "TEST"
	set main_folder to (make new folder at desktop with properties {name:folder_name})
	set desktop position of main_folder to {1000, 50, 100, 100}
	set current view of container window of main_folder to column view
	open main_folder
	set position of Finder window 1 to {605, 100}
end tell

Nope.

Not make new folders. Open a folder that’s on the SAN, in a positioned window, in column view.

Assuming the SAN’s mounted:

--- Edit these values as required:
set targetFolder to "HFS path:to:folder:"
set targetPosition to {100, 100} -- h,v coordinates (top left origin) of top left-hand corner of window.
-- Or:
-- set targetBounds to {100, 100, 1100, 800} -- h,v,h,v coordinates (ditto) of top left and bottom right corners.

tell application "Finder"
	activate
	set w1 to (make new Finder window to folder targetFolder)
	tell w1
		set {current view, position} to {column view, targetPosition}
		-- Or:
		-- set {current view, bounds} to {column view, targetBounds}
	end tell
end tell

Or perhaps:

-- Edit these values as required:
set targetFolder to "HFS path:to:folder:"
set targetPosition to {100, 100} -- h,v coordinates (top left origin) of top left-hand corner of window.
-- Or:
-- set targetBounds to {100, 100, 1100, 800} -- h,v,h,v coordinates (ditto) of top left and bottom right corners.

tell application "Finder"
	activate
	tell (make new Finder window to folder targetFolder) to set {current view, position} to {icon view, targetPosition}
	-- Or:
	-- tell (make new Finder window to folder targetFolder) to set {current view, bounds} to {icon view, targetBounds}
end tell

I tried the latter. The very reason I want to do this is to mount this actual folder on the SAN volume.

But it is currently mounted and I tried it. It said it can’t get the folder.

error “Finder got an error: Can’t get folder "Volumes:RFstor:storMusic:Music:".” number -1728 from folder “Volumes:RFstor:storMusic:Music:”

This isn’t mentioned in either of your previous posts. You should check out the ‘mount volume’ command in the StandardAdditions.

HFS paths don’t begin with “Volumes”. “RFstor:storMusic:Music:”.

Yes, I know. Well, yes, it was.

/Volumes…

is just that. It was suggested to me that I use HFS. I wasn’t suggesting that at all. I’m the one asking the question. But thanks for the guidance. I’ll give it a try.