Search for file in folders and subfolders

Thanks Shane. That simplifies the script and makes it more reliable to boot.

Just a note to Carl. The following script assumes that the here_i_am file is directly located in the folder that begins with the company prefix. If the here_i_am file is located in a subfolder of the folder that begins with the company prefix, you can delete the line that begins with “set thePred” and remove the comment characters from the next line, which also begins with “set thePred”.

use scripting additions
use framework "Foundation"

on main()
	set searchPath to "/Volumes/Store/Test/" -- this should be path to folder on server
	set sourceFile to (choose file)
	
	set ATID to AppleScript's text item delimiters
	set AppleScript's text item delimiters to {":"}
	set sourceFileName to text item -1 of (sourceFile as text)
	set AppleScript's text item delimiters to {"-"}
	set theCompanyPrefix to text item 1 of sourceFileName
	set theCompanyName to text item 2 of sourceFileName
	set AppleScript's text item delimiters to ATID
	
	set locationFileName to theCompanyName & "-here_i_am.txt"
	set targetFolder to getFiles(searchPath, locationFileName, theCompanyPrefix)
	
	tell application "Finder" to duplicate sourceFile to targetFolder with replacing
end main

on getFiles(theFolder, theName, theCompanyPrefix)
	set theFolder to current application's |NSURL|'s fileURLWithPath:theFolder
	set fileManager to current application's NSFileManager's defaultManager()
	set folderContents to (fileManager's enumeratorAtURL:theFolder includingPropertiesForKeys:{} options:((current application's NSDirectoryEnumerationSkipsPackageDescendants) + (current application's NSDirectoryEnumerationSkipsHiddenFiles as integer)) errorHandler:(missing value))'s allObjects()
	set thePred to current application's NSPredicate's predicateWithFormat_("(lastPathComponent ==[c] %@) AND (URLByDeletingLastPathComponent.lastPathComponent BEGINSWITH[c] %@)", theName, theCompanyPrefix)
	-- set thePred to current application's NSPredicate's predicateWithFormat_("(lastPathComponent ==[c] %@) AND (path  CONTAINS[c] %@)", theName, theCompanyPrefix)
	set theFiles to (folderContents's filteredArrayUsingPredicate:thePred)
	if (count theFiles) = 0 then errorDialog("No location files were found")
	return ((theFiles's URLByDeletingLastPathComponent) as alias)
end getFiles

on errorDialog(dialogText)
	display dialog dialogText buttons {"OK"} default button 1 cancel button 1 with title "" with icon stop
end errorDialog

main()

I had a question and hoped Shane or other forum member could help.

The predicate Shane suggests as a possible solution is:

(URLByDeletingLastPathComponent.lastPathComponent BEGINSWITH[c] %@)

This works if the lastPathComponent begins with %@, which we’ve defined in this thread as theCompanyPrefix. This doesn’t work if theCompanyPrefix is at the beginnning of a folder that is not the lastPathComponent. My tentative solution is:

(path CONTAINS[c] %@)

This is somewhat less reliable because theCompanyPrefix might be found elsewhere in a folder name, and this is not the desired result. I looked at the documentation and thought perhaps pathComponents might be used to accomplish this but pathComponents returns an array and I don’t know how to check each item of the array to see if it begins with %@ (i.e. theCompanyPrefix). I tried the following:

(pathComponents BEGINSWITH[c] %@)

Pretty much as expected, my script with the above predicate returned:

The OP has indicated that theCompanyPrefixes are unique, so I think my existing solution is workable, but I’d like to understand this just for learning purposes.

Thanks.

The result of pathComponents is an array (a list), you cannot apply the BEGINSWITH predicate to an array.

The only way is Regular Expression

(path MATCHES[c] %@)

and for %@ write

("/" & theCompanyPrefix)

The predicate evaluates to true if there is (at least) one occurrence of a slash followed by the prefix

Stefan. Thanks for responding to my post.

I tried your suggestion, which made great sense, but it didn’t seem to work. Instead, the next line of the script, which begins with “set theFiles”, returned no files when there were matching files.

I replaced MATCHES with CONTAINS and the script seemed to work as desired and appeared to enforce the requirement that theCompanyPrefix be at the front of a folder name.

set thePred to current application's NSPredicate's predicateWithFormat_("(lastPathComponent ==[c] %@) AND (path CONTAINS[c] %@)", theName, ("/" & theCompanyPrefix))

Is there any advantage to using MATCHES or do I not understand your suggestion?

@Peavine, Shane & StefanK.

Thanks a lot to all of you.

My impression is, that you really do high-end scripting here and as total beginner there is nothing I could contribute. Right know I try to understand the expressions you use to figure out a little bit how this works.

@Peavine
You mentioned three options a few posts earlier and thankfully you offer and solution for option 3.

I just like to mention why option 1 maybe a little bit faster in my case, but maybe I am wrong:

The here_i_am file is located somewhere in the sub-sub-folder depths of the searchFolder (i.e.theCompanyPrefix-something).

But the searchFolder is only one of many folders of its parent folder. And each of the siblings folders has a wide subfolder structure. Therefore I guess it would be efficient to identify the searchFolder in the first place to narrow and maybe speed up the search for the here_i_am file.

The here_i_am file is unique in the whole folder structure, so a global search may also work.

I just wanted to let you know this background just for the case that it’s of interest for you.
I myself will try to study the posts and try and study the solutions to learn even more.

Thanks again
Carl

Most likely you have to escape the slash

set thePred to current application's NSPredicate's predicateWithFormat_("(lastPathComponent ==[c] %@) AND (path MATCHES[c] %@)", theName, ("\\/" & theCompanyPrefix))

Regular Expression is much more powerful than standard contains for example the pattern

[format]\/[ABC][123]\s?[/format]

finds every (sub)string which starts with a slash followed by A, B or C followed by 1, 2 or 3 followed by a optional whitespace character

Carl. Having given the matter some more thought, the script proposal I identified as option 1 would not work well. So, I have included below my best suggestion, which seems to meet all your requirements. While I was at it, I included the ability to select several copy-me files in the dialog. I tested this script without issue but let me know if you encounter any issues.

use scripting additions
use framework "Foundation"

on main()
	set searchPath to "/Volumes/Store/Test/" -- this should be path to folder on server
	set sourceFiles to (choose file with multiple selections allowed)
	
	set ATID to AppleScript's text item delimiters
	repeat with aFile in sourceFiles
		set AppleScript's text item delimiters to {":"}
		set sourceFileName to text item -1 of (aFile as text)
		set AppleScript's text item delimiters to {"-"}
		set theCompanyPrefix to text item 1 of sourceFileName
		set theCompanyName to text item 2 of sourceFileName
		set locationFileName to theCompanyName & "-here_i_am.txt"
		set targetFolder to getFiles(searchPath, locationFileName, theCompanyPrefix)
		tell application "Finder" to duplicate aFile to targetFolder with replacing
	end repeat
	set AppleScript's text item delimiters to ATID
end main

on getFiles(theFolder, theName, theCompanyPrefix)
	set theFolder to current application's |NSURL|'s fileURLWithPath:theFolder
	set fileManager to current application's NSFileManager's defaultManager()
	set folderContents to (fileManager's enumeratorAtURL:theFolder includingPropertiesForKeys:{} options:((current application's NSDirectoryEnumerationSkipsPackageDescendants) + (current application's NSDirectoryEnumerationSkipsHiddenFiles as integer)) errorHandler:(missing value))'s allObjects()
	set thePred to current application's NSPredicate's predicateWithFormat_("(lastPathComponent ==[c] %@) AND (path MATCHES[c] %@)", theName, (".*?/" & theCompanyPrefix & ".*"))
	set theFiles to (folderContents's filteredArrayUsingPredicate:thePred)
	if (count theFiles) = 0 then display dialog "A location file was not found for company " & theCompanyPrefix buttons {"OK"} cancel button 1 default button 1 with icon stop
	return ((theFiles's URLByDeletingLastPathComponent) as alias)
end getFiles

main()

Thanks Stefan. I still can’t get that to work–I suspect I’m doing something wrong. I’m working to learn predicates and I’ll include the MATCHES operator in my studies.

Sorry, my bad, unlike NSRegularExpression the MATCHES pattern must cover the entire string, so we have to add wildcard characters at the beginning and the end

set thePred to current application's NSPredicate's predicateWithFormat_("(lastPathComponent ==[c] %@) AND (path MATCHES[c] %@)", theName, (".*?/" & theCompanyPrefix & ".*"))

Stefan. I tested that and it worked great. Thanks.

Hi peavine,

thank you very much again.
In my setup environment the script works just fantastically and it’s very fast. One file takes just about a second.

In the real environment I have some issues with speed and I guess it has something to do with network (NAS SMB sharing over LAN) or my adaption to the real world environment.
I had to interrupt one try after about 2 hours.

Then I cheated a little bit and narrowed the search to theSearchfolder (i.e.theCompanyPrefix-something) by changing the line:

set searchPath to “/Volumes/Store/Test/theCompanyPrefix-something/”

I’m not sure if that even made sense because I couldn’t figure out if your last version does a general search for the here_i_am file or if the search is already narrowed by the script to the folder theCompanyPrefix-something. Anyway with this cheat, it took about 5 minutes to do the search and copy the file successfully but the cheat won’t help me with the task in real life.

So I’m not sure, what to do next. It was possible, to even narrow the search one level down to the next subfolder which is named like ‘theCompanyPrefix-communication’.

Therefore I tried to unparse line with the NSPredicate but I didn’t succeed yet. I hope to find some developer documentation on the internet, that might help me with that. So I don’t give up an I’m still on it.

I’m really very thankful for your fantastic help so far and I humbly don’t want to bother you too much and steal your time.

Kind regards
Carl

Carl. If the script takes more than a minute or so to run then something is definitely wrong. Unfortunately, I’m not knowledgeable about servers and can’t even begin to suggest a solution in that regard.

One option that would be easy to implement is to limit the search path based on the company prefix, and this would go after the company name and prefix are parsed. For example,

if companyPrefix = "abcd" then
	set searchPath to "/Volumes/Store/Test/abcd-something"
else if companyPrefix = "xxxx" then
	set searchPath to "Volumes/Store/Test/xxxx-something"
end if

If I understand correctly, this will not work in your situation.

BTW, when searching for specified disk items, ASObjC first gets all files/folders in the search folder and then filters those items using specified rules (see code segment below). All of my suggested scripts work that way, and this is normally quite quick. Perhaps another forum member will suggest a different approach.

-- get all files/folders in theFolder but skip hidden files and the contents of packages
set folderContents to (fileManager's enumeratorAtURL:theFolder includingPropertiesForKeys:{} options:((current application's NSDirectoryEnumerationSkipsPackageDescendants) + (current application's NSDirectoryEnumerationSkipsHiddenFiles as integer)) errorHandler:(missing value))'s allObjects()

-- set the filter rules which in this case are 1) a specific file name, and
-- the file name''s path contains theCompanyPrefix
set thePred to current application's NSPredicate's predicateWithFormat_("(lastPathComponent ==[c] %@) AND (path MATCHES[c] %@)", theName, (".*?/" & theCompanyPrefix & ".*"))

-- apply the filter to the found files
set theFiles to (folderContents's filteredArrayUsingPredicate:thePred)

Thank you for the quick response Peavine,

Yes you’re right… in my situation narrowing the search path doesn’t work, because…

A) There are too many companyPrefixes to take them into account in the script,
B) the ‘something’ in the folder name can be any expression and therefore cannot be defined in the Script.

Thank you very much for the quick insight into ASObjC…
For me as a beginner it seems to be quite sophisticated, but I also find it interesting and so I’ll try to experiment a little bit with it.

Hi Stefan,

thank you very much for your help. Right now I’m trying to figure out how to adapt the script even more to my real world environment.

Maybe you can give me a little hint where I can find some information about the expressions in that lines below. Despite Google I haven’t found a way to unparse the expressions.

Thanks again,
Carl

• .* means 0 or more (any) characters, the period represents “any character” the asterisk represents “0 or more”
• ? The previous expression is optional. In this case it’s redundant and can be omitted
• / a slash
• the prefix

Here is a Quick Reference: https://koenig-media.raywenderlich.com/downloads/RW-NSRegularExpression-Cheatsheet.pdf

Thank you again. Very helpful. The PDF is great.

I haven’t found anything about…
==[c] %@)
Is this also part of the NSRegularExpression set?

Cheers
Carl

No, it’s part of the NSPrediate syntax, [c] means case insensitive and %@ is a placeholder for the first parameter after the comma, theName

For those, who like plain AppleScript solution:


-- file to search
property fileName : "Tless0.tiff"
-- file to copy
set fileToCopy to "HARD_DISK:Users:123:Downloads:TEST files:Abstract Background.ai"
-- were to search
set chosenFolder to (path to downloads folder) as text

-- coerce HFS path to System Events folder reference
tell application "System Events" to set chosenFolder to folder chosenFolder

-- maybe, the file doesn't exist at all. So, we use here TRY block
try
	set parentFolder to my recurse(chosenFolder)
	tell application "Finder" to duplicate file fileToCopy to folder parentFolder
end try

-- recursive handler
on recurse(chosenFolder)
	tell application "System Events"
		if (fileName is in (name of files of chosenFolder)) then
			return path of chosenFolder -- local exit from handler
		else
			repeat with subFolder in (get folders of chosenFolder)
				my recurse(subFolder)
				try
					return result -- global exit from handler
				end try
			end repeat
		end if
	end tell
end recurse

Very interesting, thank you for the help.
I made some progress by studying the Predicate Programming Guide by Apple.

But in the samples there the ‘predicateWithFormat’ expression is always followed by ‘:@’, like ‘predicateWithFormat:@’

Whereas in the given line…

set thePred to current application’s NSPredicate’s predicateWithFormat_(“(lastPathComponent ==[c] %@) AND (path MATCHES[c] %@)”, theName, (“.?/" & theCompanyPrefix & ".”))

the expression ist follwoed by ‘(’ like 'predicateWithFormat(’

Can you help me once more?

Cheers
Carl

«underscore-parentheses» and «colon» are synonyms, the former is legacy syntax, the latter is more convenient (and ObjC-compatible), however sometimes with complex expressions the former is still useful.