In case you’re interested, j, I’d produced something similar earlier - which should filter out any recent item ‘types’ not specified in the Appearance prefs pane of System Preferences. Offered purely for comparison (to those who don’t use third-party software to modify Mac OS X file structures ;)):
to get_aliases from l
set f to (path to temporary items as Unicode text) & "aliasData.dat"
set r to (open for access file f with write permission)
repeat with i in l
set eof r to 0
write i to r
try
set i's contents to (read r from 1 as alias) as Unicode text as alias
on error
set i's contents to false
end try
end repeat
close access r
end get_aliases
tell application "System Events" to tell property list file ((path to preferences as Unicode text) & "com.apple.recentitems.plist")
set l to property list items whose name of property list items contains "CustomListItems"
repeat with t in l
if value of t's property list item "MaxAmount" > 0 then set t's contents to t's name
end repeat
set l to l's every Unicode text
set c to count l
if c is 0 then return beep
if c > 1 then
set p to "Choose type(s) of recent item:"
if l contains "Servers" then set p to p & return & "(Servers must be mounted)"
tell me to set l to choose from list l with prompt p with multiple selections allowed
end if
if l is false then error number -128
set r to {}
repeat with i in l
set r to r & value of property list item "Alias" of property list items of property list item "CustomListItems" of property list item i
end repeat
end tell
get_aliases from r
tell application "Finder" to set l to sort r's aliases by modification date
set n to {}
repeat with i in l
set n's end to i's name
end repeat
set c to choose from list n with prompt "Choose item(s) to open:" with multiple selections allowed
if c is false then error number -128
repeat with i from 1 to count n
if n's item i is in c then open l's item i
end repeat