In an effort to locate things on my dual-screen setup without shoving them up against the menu bar or under the dock on my primary screen, I put this together. It returns nearly everything you might want to know about dual screens - errors if you have only one [This was fixed to allow a primary screen on either port of a dual-screen card and the menu bar to be on either screen - thanks to Rick Smykla for pointing out the flaws and testing].

Applescript:

to GetScreenParameters()
   tell (do shell script " defaults read /Library/Preferences/com.apple.windowserver | grep -w -m 2 Unit") to if word 3 = word 6 then return display dialog "There is only one screen attached to this computer!" buttons {"Oops"} default button 1 giving up after 5 with icon 2
   tell (do shell script "echo `defaults read /Library/Preferences/com.apple.windowserver | grep -wA 1 -m 2 OriginX``defaults read /Library/Preferences/com.apple.windowserver | grep -w -m 2 Height``defaults read /Library/Preferences/com.apple.windowserver | grep -w -m 2 Width``defaults read /Library/Preferences/com.apple.windowserver | grep DisplayLayoutToRight``defaults read com.apple.dock | grep orientation``defaults read com.apple.dock | grep tilesize`") to set details to {word 3, word 6, word 9, word 12, word 15, word 18, word 21, word 24, word 27, word 30, word 33}
   
   --> Origin1 x, y; Origin2 x, y; Height 1, 2; Width 1, 2; DisplayLayout 1 = Right; DockPosition 0 = Left; DockSize; Extent x, y. The screen with origin 0, 0 has the menu bar, or if Display2toRight = 1, then the menu bar is on the left.
   
   repeat with anItem in details -- not really necessary, but I wanted numbers.
       try
           set contents of anItem to contents of anItem as number
       end try
   end repeat
   
   tell application "Finder" to tell (bounds of desktop's window) as list to set details to details & {(item 3) - (item 1), (item 4) - (item 2)}
   tell details to return {OriginPrimaryX:item 1, OriginPrimaryY:item 2, Origin2X:item 3, Origin2Y:item 4, HeightPrimary:item 5, Height2:item 6, WidthPrimary:item 7, Width2:item 8, Display2toRight:item 9, DockPosition:item 10, DockSize:item 11, WidthDesk:item 12, HeightDesk:item 13}
end GetScreenParameters

GetScreenParameters()
--> {OriginPrimaryX:0, OriginPrimaryY:0, Origin2X:1152, Origin2Y:156, HeightPrimary:870, Height2:768, WidthPrimary:1152, Width2:1024, Display2toRight:1, DockPosition:"left", DockSize:36, WidthDesk:2176, HeightDesk:924}