Welcome to AppleScript, Pineapple.

Pineapple wrote:

1. The first problem I have is with my pages_filename function. It doesn’t return a filename with the full path of the original file e.g. HD:folder:folder:filename.pages.
I don’t know how to get the original path off the filename so I can concatenate it to the new filename.  Please could someone tell me how?

Here's one possibility:

Applescript:

on parentFolder for someItem
   -- `someItem` should be an alias, a file specification, or text
   set someItem to "" & someItem -- Coerce to text
   
   set ASTID to AppleScript's text item delimiters
   set AppleScript's text item delimiters to ":"
   try
       set someItem to text 1 thru text item -2 of someItem
   end try
   set AppleScript's text item delimiters to ASTID
   
   return someItem
end parentFolder

Pineapple wrote:

2. How do you look up what you can do with an object of a particular type for example ‘to the name of’ and ‘to the name extension of’  in the above fragments?

Well, in your example, you're getting that information from the `info for` command, which is part of Standard Additions (a scripting addition, or OSAX). If you go to Script Editor's File meun and choose "Open Dictionary…", then you will be shown a list of scriptable applications and scripting additions. Choose Standard Additions from the list, and you will see (and be able to search through) quite a few useful commands.

Side note: `info for` returns a record, which is conceptually comparable (there are some limitations) to associative arrays in other languages.

Side note: Here's another way of getting the name without an extension (thanks to Adam Bell for this one):

Applescript:

on nameWithoutExtension for someAlias
   -- `someAlias` should be an alias or file specification
   tell (info for someAlias) to return text 1 thru ((my (offset of ("." & name extension & ":") in (name & ":"))) - 1) of name
end nameWithoutExtension

3. There is absolutely no error handling in here at the moment, what should I build in?

For repeat loops, I prefer to use something like this:

Applescript:

repeat with thisItem in theseItems
   try
       -- do something
   on error errMsg number errNum
       display dialog "Error " & return & return & errMsg with icon caution buttons {"Cancel Script", "Skip Item"} default button 2
       if button returned of result is "Cancel Script" then error number -128 -- cancel
   end try
end repeat

Side note: If your script will only be running on Mac OS X v10.4 or later, you can use the better looking `display alert` command:

Applescript:

repeat with thisItem in theseItems
   try
       -- do something
   on error errMsg number errNum
       display alert "Error " & errNum message errMsg as warning buttons {"Cancel Script", "Skip Item"} cancel button 1 default button 2
   end try
end repeat

See also: Try Statements