You are not logged in.
#1 2006-08-24 12:14:41 pm
- Bruce Phillips
- Administrator
- Registered: 2004-07-15
- Posts: 2647
Join List [Implode]
Applescript:
-- delimiter : The delimiter used to join the text.
-- someList : The list to be joined.
--
on joinList(delimiter, someList)
set prevTIDs to AppleScript's text item delimiters
set AppleScript's text item delimiters to delimiter
set output to "" & someList
set AppleScript's text item delimiters to prevTIDs
return output
end joinList
-- Example
joinList(",", {"a", "b", "c", "d", "e"})
See also:
Split or Explode Text
http://brucep.net/code/applescript/join-list
Last edited by Bruce Phillips (2008-01-14 08:45:53 pm)
Offline
#2 2006-08-24 03:46:52 pm
- John M
- Member
- Registered: 2003-07-14
- Posts: 384
Re: Join List [Implode]
Hi,
Here's a two way function. Turn lists into text, and text into lists.
Applescript:
-- If object is a list makes text.
-- If object is text makes a list.
on implode_explode(separator, object)
set {ASTID, my text item delimiters} to {my text item delimiters, {separator}}
if class of object is list then
set object to object as Unicode text
else
set object to text items of object
end if
set my text item delimiters to ASTID
return object --> text or list
end implode_explode
Applescript:
set myList to {"a", "b"}
set mySep to " "
implode_explode(mySep, myList) -->"a b"
set myText to "a b"
set mySep to " "
implode_explode(mySep, myText) -->{"a", "b"}
Last edited by John M (2006-08-24 03:48:31 pm)
Offline
