None of the extremely scarce solutions helped. My script is as follows:
tell application id "com.apple.AddressBook"
run
repeat with anObj in feeds_add
set feed_info to anObj's contents
set img_pic to missing value
if feed_info's feed_image is not data then set img_pic to feed_info's feed_image
set {feed_email_1, feed_email_2} to {feed_info's feed_name, feed_info's feed_url}
repeat with anObj in whatuse
set _contact to make new person with properties {first name:feed_email_1, company:true, image:img_pic} at end of people
tell _contact
repeat with mprop in {feed_email_1, feed_email_2}
make new email with properties {label:"other", value:mprop's contents} at end of emails
end repeat
make new url with properties {label:"homepage", value:feed_email_2} at end of urls
end tell
set grp_id to anObj's contents
add _contact to group id grp_id
end repeat
end repeat
if unsaved then save
end tell
Every variable is defined, and the group exists. Still, this error keeps hitting me. Why?
Your script is missing the code that populates the list ‘feeds_add’
In my script, feeds_add stores records. It’s fine. I skipped it here intentionally.
HI.
I can reproduce the error if the target group isn’t in the default account set in the “General” tab of Contacts’s “Settings…”.
So, the group in my script isn’t the default account. Does that mean there’s no hope? If it does, it nullifies the purpose of my code, which is to target specific groups outside of the default account.
Even weirder is that it won’t let me duplicate the new contact to a wanted group.
If those groups are all in the same non-default account, you could temporarily change the default setting in Contacts (“Contacts” menu → “Settings…” → “General”) before running the script. Or, if you’re feeling brave, you could use ASObjC and the “Contacts” framework.
If I’m guessing correctly, the modus operandi when a contact’s saved is that it’s saved to a particular account. Then, if required, links can be set up to register it as a member of one or more groups in that account. The Contacts application’s AppleScript implementation doesn’t offer a way to specify particular accounts, so the only option is saving to the currently set default account. With the “Contacts” framework though, you can either assume the default account or explicitly specify one.
The script below illustrates how this can be done. It’s written in the context of your script excerpt above, but obviously I don’t know what your data are or how you’re getting them and much of their treatment in the excerpt doesn’t make a lot of sense. 
use AppleScript version "2.5" -- OS X 10.11 (El Capitan) or later
use framework "Foundation"
use framework "Contacts"
-- Make sure the application can't interfere while the script's running.
tell application "Contacts" to if (running) then quit
set ca to current application
set contactStore to ca's CNContactStore's new()
-- A list of the target group IDs. Use your own. They'll be the same as in the Contacts application.
set targetGroupIDs to {"0B0C388E-DB00-4168-8DEC-CB5CDC67C9B3:ABGroup", "16601373-1916-4B67-A546-C30BCBD29C6A:ABGroup"}
-- Assuming they're all in the same account, get the account's ID.
set accountPred to ca's CNContainer's predicateForContainerOfGroupWithIdentifier:(targetGroupIDs's beginning)
set theAccount to (contactStore's containersMatchingPredicate:(accountPred) |error|:(missing value))'s firstObject()
set accountID to theAccount's identifier()
-- Get the groups themselves as an array of CNGroup objects.
set groupPred to ca's CNGroup's predicateForGroupsWithIdentifiers:(targetGroupIDs)
set targetGroups to contactStore's groupsMatchingPredicate:(groupPred) |error|:(missing value)
-- Partial translation of scrutinizer82's code.
set {feed_email_1, feed_email_2} to {"fred@bns.com", "bert@bns.com"}
-- Initialise a mutable contact.
set _contact to ca's CNMutableContact's new()
-- Set it to be an organization.
_contact's setContactType:(ca's CNContactTypeOrganization)
-- Set its first name (but preferably its organization name if it's an organization).
_contact's setGivenName:(feed_email_1) -- _contact's setOrganizationName:(feed_email_1)
-- Build an array of labelled values representing its e-mail adddress.
set emailAddresses to ca's NSMutableArray's new()
repeat with mprop in {feed_email_1, feed_email_2}
(emailAddresses's addObject:(ca's CNLabeledValue's labeledValueWithLabel:("other") value:(mprop)))
end repeat
_contact's setEmailAddresses:(emailAddresses)
-- Similarly with its URLs, although there's only one in this array.
_contact's setUrlAddresses:({ca's CNLabeledValue's labeledValueWithLabel:("homepage") value:(feed_email_2)})
-- Construct a request to save the contact in the appropriate account and to add it to the relevant groups.
set saveRequest to ca's CNSaveRequest's new()
saveRequest's addContact:(_contact) toContainerWithIdentifier:(accountID)
repeat with thisGroup in targetGroups
(saveRequest's addMember:(_contact) toGroup:(thisGroup))
end repeat
-- Execute the save request.
contactStore's executeSaveRequest:(saveRequest) |error|:(missing value)
