AppleScript to get detail from Eudora to FileMaker Pro

Scripting Forums AppleScript | Classic Mac OS
,
#1

I need to copy details of emails (from, cc, date, subject, message, attachment) received to the appropriate contact person stored in a Filemaker Pro database. My problem are:

1 date of the email: it does not recongize “message date”(see NOTE A in the script)
2. message: only copy to FileMaker Pro the second paragraph even when I use “as Styled text”
The rest of the script works Ok.
Please advise. Thanks

***************** my script *************

global tsubj, tto, tfrom, tcc, ta, tdet

tell application “Eudora”
activate
– message 0 is the selected message
set tto to field “to” of message 0
set tfrom to field “from” of message 0

if field "cc" of message 0 exists then
	set tcc to field "cc" of message 0 as string
else
	set tcc to ""
end if

if field "subject" of message 0 exists then
	set tsubj to field "subject" of message 0 as string
else
	set tsubj to ""
end if

-- (NOTE A ) DOES NOT WORK ????

– set tdate to field “message date” of message 0

-- field "" is the body
set tdet to field "" of message 0 as styled text

-- allow for 2 attachments
if attachment 1 of message 0 exists then
	set ta1 to (attachment 1 of message 0) as string
	copy ta1 to ta
end if
if attachment 2 of message 0 exists then
	set ta2 to (attachment 2 of message 0) as string
	copy ta & ";" & ta2 to ta
end if

end tell

tell application “FileMaker Pro”
activate
– set the path a file name of the db
set tfile to “Macintosh HD:Projects:AMSI:Tracking.fp5”

--This opens the db or brings it to the front if already open
open tfile

set data field "tto" to tto
set data field "tfrom" to tfrom
copy tcc to field "tcc"
set data field "tsubj" to tsubject
set data field "tdetail" to tdet as styled text
if "ta" > "" then
	set data field "ta" to ta
end if

-- do script "clean"

end tell

#2

Maybe this will fix the Eudora part of the script.

global tsubj, tto, tfrom, tcc, ta, tdet

tell application "Eudora"
	activate
	-- message 0 is the selected message. message "" is another way to refer to it, as is  front message
	set mess_ to a reference to message 0
	tell mess_
		set tto to field "To"
		set tfrom to field "from"
		
		if field "cc" exists then
			set tcc to field "cc" as string
		else
			set tcc to ""
		end if
		
		if field "subject" exists then
			set tsubj to field "subject" as string
		else
			set tsubj to ""
		end if
		
		-- (NOTE A ) DOES NOT WORK ???? Maybe it does now. ;-)
		set tdate to message date
		
		-- field "" is the body 
		set tdet to field "" as styled text
		
		-- allow for 2 attachments 
		if attachment 1 exists then
			set ta1 to (attachment 1) as string
			copy ta1 to ta
		end if
		if attachment 2 exists then
			set ta2 to (attachment 2) as string
			copy ta & ";" & ta2 to ta
		end if
	end tell
end tell

Note: Not all messages have a To field. :wink:

– Rob