CS3 InDesign failure to set bleeds

Scripting Forums AppleScript | Mac OS X
,
#1

I’m trying to set bleeds (something like:

 	tell (print preferences)
		set bleed top to 9
		set bleed bottom to 9
		set bleed inside to 9
		set bleed outside to 9
	end tell

) but they only seem to be gettable in a document, and I can’t see where to set them.

tia
rhb

#2

Hi,

the dictionary says: Valid only when use document bleed to print is true.
Maybe this is the reason


tell (print preferences)
	set bleed top to 9
	set bleed bottom to 9
	set bleed inside to 9
	set bleed outside to 9
	set use document bleed to print to true
end tell
#3

Stefan,
thanks, I hadn’t noticed that however my main problem is that the print preferences seem to be get only at both the document and application level.
I always get “Adobe InDesign CS3 got an error: Can’t set set” bleed top to 9 or use document bleed to print of print preferences to true etc.
If I do something like:

set tempdoc to make new document with properties {print preferences:{use document bleed to print:true, bleed top:9, bleed bottom:9, bleed inside:9, bleed outside:9, bleed chain:true}}

I don’t get an error but I don’t get bleeds either

I appreciate your help, thanks again

rhb

#4

It looks like you need to specify a size with a string, like “1inch” or “2p”

Also, you gotta use the right terminology and heirarchy.

The document has a bleed setting: document preferences > document bleed bottom offset (etc) which actually sets a bleed line in the document.
Print Preferences has a different setting: print preferences > bleed bottom (etc) which only applies to print output

If you want a document bleed try this:

tell application "Adobe InDesign CS3"
	set tempdoc to make new document
	tell tempdoc
		tell document preferences
			set document bleed uniform size to false
			set document bleed inside or left offset to "3p"
			set document bleed top offset to "2p"
		end tell
	end tell
end tell

or your script works if you quote the value you want:

tell application "Adobe InDesign CS3"
	set tempdoc to make new document with properties {print preferences:{use document bleed to print:false, bleed top:"9p", bleed bottom:"9p", bleed inside:"9p", bleed outside:"9p", bleed chain:true}}
end tell
#5

Hi

This is straight from the indesign_cs3_guide_scripts

--BleedAndSlug.applescript
--An InDesign CS3 AppleScript
--Shows how to define the bleed and slug areas of a document.
tell application "Adobe InDesign CS3"
	--Create a new document.
	set myDocument to make document
	--The bleed and slug properties belong to the document preferences object.
	tell document preferences of myDocument
		--Bleed
		set document bleed bottom offset to "3p"
		set document bleed top offset to "3p"
		set document bleed inside or left offset to "3p"
		set document bleed outside or right offset to "3p"
		--Slug
		set slug bottom offset to "18p"
		set slug top offset to "3p"
		set slug inside or left offset to "3p"
		set slug right or outside offset to "3p"
	end tell
end tell

Budgie

#6

Great guys!

Thanks for all the help

I’m a happy bleeding camper now :slight_smile: