Excel-copy a range from multiple files into a single workbook

Scripting Forums Code Exchange
#1

This is code written by Stefan in response to some problems I was having. Works like a charm. I’ve made very minor modifications. Credit is his. http://bbs.macscripter.net/viewtopic.php?pid=99053#p99053

set sourceFolder to (path to desktop folder as Unicode text) & "paninsal:"

tell application "Finder" to set theFiles to (every file of folder sourceFolder whose name extension is "csv") as alias list
tell application "Microsoft Excel" to set theWkbk to open workbook workbook file name sourceFolder & "fed.xls"

repeat with oneFile in theFiles
   set thisName to name of (info for oneFile)
   tell application "Microsoft Excel"
       set screen updating to false
       open oneFile
       tell sheet 1 of theWkbk
           set range_value to value of used range
           if class of range_value is list then
               set firstUnusedCellA to (count range_value) + 1
           else
               set firstUnusedCellA to 2
           end if
           set value of cell 1 of row firstUnusedCellA to thisName
       end tell
       set destinationRange to "A" & (firstUnusedCellA + 1) & ":E" & (firstUnusedCellA + 90)
       copy range (range "A1:E90" of sheet "Sheet1" of workbook thisName) destination range destinationRange of sheet 1 of theWkbk
       close workbook thisName saving no
       set screen updating to true
   end tell
end repeat