How can I use a Positional Parameters handler in Cocoa Applescript

[mcquiff]

I’m trying for the first time to use xCode and the problem I am running into is how to use a Position handler in the code?

How do I enter the on DisplayName (x,y) and how do I call it from the Xcode? I’m an extreme newbie. So If you know of any suitable video tutorials that define this that would be great.
Many Thanks

set xPress to "Matt"
set yPress to "Child"

my DisplayName(xPress, yPress)

on DisplayName(x, y)
	display dialog x & " " & y
end DisplayName

[Shane_Stanley]

What you have will work. The question, though, is how you are calling the handler.

What are you trying to do, exactly?

[mcquiff]

as I mam just playing I was attempting to add a drop down box for label colour, add a load images button, and then a process button.

This is the script I’m using (that works)

try
	set myFile to ((path to desktop as Unicode text) & "SelectedImages.txt") as alias -- alias
on error
	set myFile to choose file name default name "SelectedImages.txt" default location (path to desktop)
end try
set resultFiles to (choose file with multiple selections allowed) -- list of aliases

-- clear existing contents of myFile
my write_to_file("", myFile's POSIX path, {_append:false, _class:«class utf8»})

repeat with f in resultFiles
	set f to f's contents
	-- append f's HFS path & return to myFile
	my write_to_file("" & f & return, myFile's POSIX path, {_append:true, _class:«class utf8»})
	
	-- set f's Finder label index to 2 (red)
	tell application "Finder"
		set f's label index to 2 --red
	end tell
end repeat

on write_to_file(x, p, {_append:_append, _class:_class})
	(*
        anything x : anything to be written to output file
        string p : POSIX path of output file
        boolean _append: true to append data, false to replace data
        type class _class: type class as which the data is written
    *)
	local fd
	try
		set fd to open for access (POSIX file p) with write permission
		if not _append then set eof fd to 0
		write x as _class to fd starting at eof
		close access fd
	on error errs number errn
		try
			close access (POSIX file p)
		end try
		error "write_to_file(): " & errs number errn
	end try
end write_to_file

This is what I have written in the app delegate

script AppDelegate

property LabelColor: ""

property resultFiles : ""


on labelColorButton0_(sender)
    set LabelColor to "0"
end labelColorButton0_

on labelColorButton1_(sender)
    set LabelColor to "2" --red
end labelColorButton1_

on labelColorButton2_(sender)
    set LabelColor to "1" --orange
end labelColorButton2_

on labelColorButton3_(sender)
    set LabelColor to "3" --yellow
end labelColorButton3_

on labelColorButton4_(sender)
    set LabelColor to "6" --green
end labelColorButton4_

on labelColorButton5_(sender)
    set LabelColor to "4" --blue
end labelColorButton5_

on labelColorButton6_(sender)
    set LabelColor to "5" --magenta
end labelColorButton6_

on labelColorButton7_(sender)
    set LabelColor to "7" --grey
end labelColorButton7_


on loadedFiles_(sender)
    set resultFiles to (choose file with multiple selections allowed) -- list of aliases
end loadedFiles_

on pageMaker_(sender)
    activate
    tell application "Finder"
        set thePath to (path to application id "com.adobe.Photoshop")
        set ParentFolder to (container of thePath) as text
        set PresetsFolder to (ParentFolder & "Presets:")
        if exists folder (PresetsFolder & "ScriptsData") then
            set ScriptsData to (PresetsFolder & "ScriptsData:") as text
            log ScriptsData
            else
            set ScriptsData to (make new folder at PresetsFolder with properties {name:"ScriptsData"}) as text
            log ScriptsData
        end if
    end tell
    set myFile to (ScriptsData & "SelectedImages.txt")
    
    
    my write_to_file("", myFile's POSIX path, {_append:false, _class:«class utf8»})
    
    repeat with f in resultFiles
        set f to f's contents
        -- append f's HFS path & return to myFile
        my write_to_file("" & f & return, myFile's POSIX path, {_append:true, _class:«class utf8»})
        
        -- set f's Finder label index to 2 (red)
        tell application "Finder"
            set f's label index to 2 --red
        end tell
    end repeat
    
    on write_to_file(x, p, {_append:_append, _class:_class})
        (*
         anything x : anything to be written to output file
         string p : POSIX path of output file
         boolean _append: true to append data, false to replace data
         type class _class: type class as which the data is written
         *)
        local fd
        try
            set fd to open for access (POSIX file p) with write permission
            if not _append then set eof fd to 0
            write x as _class to fd starting at eof
            close access fd
            on error errs number errn
            try
                close access (POSIX file p)
            end try
            error "write_to_file(): " & errs number errn
        end try
    end write_to_file


end pageMaker_




on applicationWillFinishLaunching_(aNotification)
	-- Insert code here to initialize your application before any files are opened
end applicationWillFinishLaunching_

on applicationShouldTerminate_(sender)
	-- Insert code here to do any housekeeping before your application quits 
	return current application's NSTerminateNow
end applicationShouldTerminate_

end script

and my error is this

OSACompile OpenSesame/AppDelegate.applescript
cd /Users/StudioA/Documents/OpenSesame
/usr/bin/osacompile -l AppleScript -d -o /Users/StudioA/Library/Developer/Xcode/DerivedData/OpenSesame-fmclzgvvakekfxbmkfonkzjufmob/Build/Products/Debug/OpenSesame.app/Contents/Resources/AppDelegate.scpt OpenSesame/AppDelegate.applescript

OpenSesame/AppDelegate.applescript:83: error: Expected “end” but found “on”. (-2741)
Command /usr/bin/osacompile failed with exit code 1

[Shane_Stanley]

You’re trying to put the write_to_file() handler inside the pageMaker_() handler – you can’t do that in AppleScript. When you get a compile error, the first thing to to do is use Open with External Editor and try to compile it there.

[mcquiff]

Sorry in wrong order… kept shifting it thinking things were in the wrong place.

Now it builds without a problem, although I do have this

error?

2014-06-05 13:31:00.897 OpenpageApp[13415:303] *** -[AppDelegate pageMaker:]: write_to_file(): Can’t make current application into type «class fsrf». (error -1700)

Is this refering to the write actions I am trying to do?

[Shane_Stanley]

You can’t use POSIX file, alias and file as specifiers in an Xcode project – you have to use them as coercions: “as POSIX file”, etc.

[mcquiff]

ah, ok. So more tinkering to do