Incrementing Build Number

[Supa_Puerco]

Is there some way in Xcode to somehow add 1 to a build number of my app each time i click build? Possibly a plugin that adds 1 to a text file containing the number inside my project?

[Supa_Puerco]

http://lists.apple.com/archives/xcode-users/2004/Jan/msg00596.html

here is a site that seems to be doing what i’m trying to do, but i get a build error every time on the shell script step.

i can’t find any other information on this for some reason. anybody? please?[/url]

[jonn8]

The following works for me in Xcode 1.5. Save this script:

–Open this script in a new Script Editor window.

tell application “Xcode”
log “Incrementing build number…”
tell project 1’s current target to set product_settings to product settings
try
set build_number to product_settings’s |CFBundleVersion| as integer
on error
set build_number to 0
end try
set build_number to build_number + 1
try
set product_settings’s |CFBundleVersion| to build_number as Unicode text
on error
set product_settings to product_settings & {|CFBundleVersion|:build_number as Unicode text}
end try
tell project 1’s current target to set product settings to product_settings
log "New build number: " & build_number
end tell

as an uncompiled AppleScript text file named “increment_build_version.applescript” and place it in the root level of your project folder. Then, in the project itself, go to the Project menu and select “New Build Phase > New Shell Script Build Phase”. This will add a new item to your target. Select the new “Shell Script Files” item in the target group and type Command-I to get its info. In the info window, leave the Shell field set to “/bin/sh” and in the Script field, enter this:

osascript “$SRCROOT/increment_build_version.applescript”

Now build your project and the version number should be incremented. Note, this is different than the CFBundleShortVersionString or CFBundleGetInfoString strings visible in the Finder that you set in the InfoPlist.strings file. This is the number that is displayed in parentheses when you show the standard about box in the application itself.

Jon

---

[This script was automatically tagged for color coded syntax by Convert Script to Markup Code]

[Supa_Puerco]

Works perfectly! This is about the millionth time you’ve saved me on something. Thanks!

[jonn8]

In Xcode v2.0, Apple has completely changed the scripting dictionary and “product settings” is no longer a property of a target (this property doesn’t exist at all for any element, actually, though it is eluded to in the description of a target). Also, “current target” has been replaced with “active target”. With these changes, you can’t use the script above to increment the build number. This script, however, using the “defaults” command line tool, should work:

–Open this script in a new Script Editor window.

tell application “Xcode”
log “Incrementing build number…”
tell project 1’s active target to set {project_directory, plist_name} to {its project’s project directory, build setting “INFOPLIST_FILE”'s value}
set the_plist to (project_directory & “/” & plist_name)'s text 1 thru -7
try
set build_number to (((do shell script “defaults read " & quoted form of the_plist & " CFBundleVersion”) as integer) + 1)
on error
set build_number to 1
end try
do shell script "defaults write " & quoted form of the_plist & " CFBundleVersion " & build_number
log "New build number: " & build_number
end tell

Still follow the same steps outlined above to actually add it a new Shell Script Build Phase.

One caveat to the above: this may change your plist from normal XML text to a binary file. It may look funny in Xcode (or in any text editor) but the system will know how to process it. Opening it in the Property List Editor app should show it to be fine. If you want to convert it back to XML from the binary file, add this line after the “defaults write” line:

–Open this script in a new Script Editor window.

do shell script "plutil -convert xml1 " & quoted form of the_plist & “.plist”

Jon

---

[This script was automatically tagged for color coded syntax by Convert Script to Markup Code]