Insert or modify Finder comments in a lot of files at once

Scripting Forums AppleScript | Mac OS X
#1

I am new here and I apologize if my request has already been answered but I have not found suitable answers.
My need is to insert or modify comments to a large number of files (about a hundred) at once.
Is there a method or a script to do this?

Then, an additional question: can someone explain to me the difference between “comment” and “Spotlight comment” in Finder?
Many thanks.

#2

There are a couple of different “comment” metadata. They are both stored as extended attributes (which get synchronized with Spotlight), but there is a slight difference in how they work with the Finder.

Finder’s comments are stored in .DSStore, which are those invisible files that get placed in every folder where Finder does stuff like comments, various views, etc. These comments get copied to the com.apple.metadata:kMDItemFinderComment extended attribute, but only if you use the Finder. If you use some other tool (command line, etc) they most likely will not be the same, as the synchronization is not consistent. The more general-purpose com.apple.metadata:kMDItemComment is not Finder-specific, so it is a bit more robust, but you need to use other tools to edit it. There is more information about these difference in this article.

Typically you would get the file items and repeat through them, adding whatever comment to each. Finder comments are easy as it has a command for them, otherwise it gets a little more involved since the comments are stored in the extended attributes as a binary property list.

1 Like
#3

Sbark. I’ve included a script suggestion below. It prompts for the desired comment for each file/folder, but you might want to use a different approach. Also, a different approach might be used to get the files/folders in a target folder.

--this script works on files/folders selected in a Finder window

tell application "Finder"
	set selectedItems to selection --can be files and/or folders
	if selectedItems is {} then error number -128 --stop script if Finder selection not found 	
	repeat with anItem in selectedItems
		set theName to name of anItem
		set existingComment to comment of anItem
		set theComment to text returned of (display dialog "Enter a comment for the file/folder named " & quote & theName & quote default answer existingComment)
		set comment of anItem to theComment
	end repeat
end tell
#4

I sincerely thank you: you are a beautiful community!

#5

A side note: Be aware that though Finder comments are normally stored in .DSStore files, sometimes they are moved from there… somewhere.* I don’t remember the details, but the simple practical thing to remember is that if your file (or folder) has Finder comment, you must always copy or move such a file (or folder) using either Finder or AppleScript. And never using shell commands, such as cp or mv. Otherwise, a comment can be lost or even changed to a different one, or “borrowed” from another file (or folder).

Also, I don’t remember whether I have tested it or not, but the same mess, probably, can occur if you restore a file (or folder) from Trash.

* And you won’t see it did happened except if you know some special secret commands. If you select your file and press Command-I, you will see your comment as usual, but in fact it was already “disconnected” from it, and you see it just because of coincidence.

#6

Red_menace’s response notwithstanding, it’s not hard to iterate through a list and update the comments attached to the files.

The biggest question is how you’re identifying the files to start with. Are you selecting them? are they all the files in a given folder? Does the script need to find them somehow?

Beyond that, the rest is easy:

use AppleScript version "2.4" -- Yosemite (10.10) or later
use scripting additions

-- the comment to add to the files
set commentToAdd to "Mary Had a Little Lamb"

tell application "Finder"
	-- get the selection. Change this line if you want to identify files some other way
	set sel to (get selection)
	-- iterate through the files
	repeat with eachItem in sel
		tell eachItem
			-- do we have a file? (i.e. ignore folders, disks, etc.)
			if its class is document file then
				-- get its current comment, for posterity
				set currentComment to its comment
				if currentComment is not "" then
					-- append our new comment to the end of the existing one
					set its comment to currentComment & return & commentToAdd
				else
					-- or just add a new comment
					set its comment to commentToAdd
				end if
			end if
		end tell
	end repeat
end tell

This comments should be self-explanatory, but feel free to ask if you have questions.

#7

I compiled a list of approaches that retained and did not retain a comment when copying or moving a file. The testing was done on my Sequoia computer, and the source file was on my boot drive. In limited testing, it did not appear to make a difference if the target folder was on my boot drive or an external APFS SSD. Fortunately, the Finder seems to do a good job in retaining comments

RETAINED COMMENT

  • Drag and drop a file in a Finder window
  • Copy and paste a file in a Finder window
  • Copy a file with Finder’s duplicate command
  • Move a file to the trash with the context menu and then restore

DID NOT RETAIN COMMENT

  • Move a file with System Events’ move command
  • Copy a file with a shortcut using a Save action (which copies files)
  • Copy a file with ASObjC using fileManager’s copyItemAtURL method
  • Copy a file with the shell’s cp command
1 Like
#8

The “Did Not Retain Comment” actions are pretty much in line with the .DSStore file not getting updated when the Finder is not involved.

Looking further, while the “Retained Comment” actions do retain the Finder comment, the com.apple.metadata:kMDItemFinderComment extended attribute is cleared. The general-purpose com.apple.metadata:kMDItemComment extended attribute is kept even when the Finder comment is not.