Move folders with a single unknown file type to their destination folder

[DJUNQUERA]

The purpose is to move the selection of images and/or videos to the corresponding image or video destination folder.

The selected folders contain only one file type, either images or videos, but not a mixture of both.

The operation is correct when a group of files is selected, even if the selection contains both types of files. However, when the selection contains folders, where you have to find out the single type of files they contain in order to send the selected folder to the appropriate destination folder, the operation is faulty.

Please, I need help to find out and fix where the error is.

Thank you very much in advance.

tell application "Finder" to set sel to selection as alias list

if sel is {} then
	display dialog "No selection found" with title " Error in selection" with icon 0 giving up after 2
	error number -128
end if

set pathFolder to "Path/to/favorite/images/folder"
set pathVideo to "Path/to/favorite/videos/folder"

tell application "Finder"
	activate
	
	repeat with i from 1 to count sel
		set targetFolder to (POSIX file pathTarget) as alias
		
		-- Is it a video?  
		if ("video" is in ((kind of item i of sel) as string)) then set targetFolder to pathVideo 
		--  is it a folder?  
		if ("folder" is in ((kind of item i of sel) as string)) then
			-- Knowing the type of files contained in the folder
			tell application "System Events" to tell process "Finder"
				keystroke "o" using command down -- open folder
				delay 0.1
				key code 125 -- select the first item (all files in the selected folder will be the same type as the first file: images or videos)
				delay 0.1
				
				tell application "Finder" to set itemFirst to selection as alias list
				set fileFirst to item 1 of itemFirst
				if (length of itemFirst = 0) or ("folder" is in ((kind of fileFirst) as string)) then
					display dialog "No item selected or the first item is again from a folder" giving up after 2
					error number -128
				end if
				
				if ("video" is in ((kind of fileFirst) as string)) then set targetFolder to (POSIX file pathVideo) as alias
				
				key code 126 using command down
			end tell
			
		end if
		
		-- duplication error ? 
		try
			set fileDuplicate to duplicate (item i of sel) to targetFolder with replacing -- ###
			delay 0.1
		on error
			display dialog "Error in the duplication of " & item i of sel with icon 0 giving up after 1
		end try
		-- error in deleting the original item ?
		try
			delete item i of sel
		on error
			display dialog "Error in the deletion of " & item i of sel with icon 0 giving up after 1
		end try
		
	end repeat
end tell

[Camelot]

Your script seems overly complex and fragile.

What’s with the use of key codes and delays. All that means is that you have to be 100% hands-off while the script is running otherwise you’re going to break things. IMHO, UI Scripting is always the last resort.

Secondly, why are you duplicating-and-then-deleting-original? why not just move the file in the first place, since that’s what your description says your script is supposed to do.

So, reading between the lines, what I hear is:

Take the current selection.
For each file in the selection, check if it’s a video or an image file
If it’s an image, move it to the Images folder (note: nothing in your current script does this, BTW)
If it’s a video, move it to the videos folder
If the selected item is a folder, check the first item in the folder, and move the entire folder based on it’s file type.

Is that about right?

In which case this is what I came up with:

use AppleScript version "2.4" -- Yosemite (10.10) or later
use scripting additions

-- properties for the destinations
property imagesPath : "/Users/andrewo/Downloads/temp/"
property videosPath : "/Users/andrewo/Downloads/temp/"

tell application "Finder"
	-- get the selected items
	set sel to (get selection)
	
	-- check we have something selected
	if sel is {} then
		display dialog "No selection found" with title " Error in selection" with icon 0 giving up after 2
		error number -128
	end if
	
	--now iterate through the selected items
	repeat with i from 1 to count sel
		-- first, assume nothing to do
		set targetFolder to ""
		
		-- get the current item
		set itemToCheck to item i of sel
		-- get its kind
		set k to kind of itemToCheck
		-- do we have a folder?
		if k is "Folder" then
			-- then refocus to the first item in the folder (note: will error if the folder is empty)
			set k to kind of item 1 of (contents of itemToCheck)
		end if
		
		-- do we have a video file?
		if k contains "video" then
			set targetFolder to videosPath
			-- or a image file?
		else if k contains "image" then
			set targetFolder to imagesPath
		end if
		
		-- do we have somewhere to move to?
		if targetFolder ≠ "" then
			move itemToCheck to POSIX file targetFolder
		end if
	end repeat
end tell

Note there are some gotchas - the script only checks if the file’s kind contains ‘video’ or ‘image’. This means that a .dmg file (a ‘disk image’) will get moved the images folder. This may or may not be a concern for you, based on your filing system, and the likelyhood of .DMG files being in the mix.

Also, it won’t catch all image or movie types. For example, a PDF document’s type is ‘PDF Document’ and therefore would be excluded. Likewise, a movie file may be a ‘QuickTime Movie’ and therefore not a ‘video’.

[DJUNQUERA]

Thank you very much, Camelot, for the clear indications with which you accompany your script (which, by the way, works perfectly).

I also appreciate your comments on the errors of approach that my script has. They will help me in the future to correct them.

In a first attempt I used the “move” command, as you have approached it.
However, it involves analyzing if the drives of the source and target items are on the same drive, since the “move” command does not delete the source item if the target is on a different drive (that was the reason why I opted to do the combined use of “duplicate” and “delete”, although it takes much more time to get the same result).
In the latter case you would have to use the “delete” command to delete the source item.

On the other hand, there is a question that, being too complicated for me, I have not even suggested it and it is the following: how could it be approached if the folder contained, in turn, more folders? That is, how to iterate over the possible subfolders?

[Camelot]

Fair point on the ‘move’ vs. ‘duplicate’ issue.

Clearly duplicate-and-delete is more work, but if it covers your use case, that’s probably easier than adding additional check code to see if the volumes match, etc.

Of course, moving to the same volume is quicker than duplicating, so some of this depends on your setup - how frequency same vs. different disks are involved, the size of the files in question, how often you’re running the script, etc. Details only you know

On the other hand, there is a question that, being too complicated for me, I have not even suggested it and it is the following: how could it be approached if the folder contained, in turn, more folders? That is, how to iterate over the possible subfolders?

Oh, totally possible, and a whole other level of scripting

It involves recursion - basically write a separate function/handler to process each file, and have the script call itself repeatedly, each time it finds a folder. The bigger question, though, is whether the script needs to maintain the original hierarchy, or merge the subfolder images… for example, given:

- folder
  |- file.jpg
  |- file 2.jpg
  |- subfolder
    |- subfile.jpg
    |- subvideo.mp4
    |- video .mp4
  |- video.mp4

moving the top level file.jpg, file 2.jpg and video.mp4 into their respective folders is easy enough (the existing script does that).
The current script will then also move the entire subfolder into the [images] folder (since its first file is an image, based on the rules defined previously).

If you want to process subfolders in this case, should the script attempt to create a [images destination]/subfolder and a [videos destination]/subfolder for the second level files? or should they be moved to the standard images and videos destinations - for that matter, how do you plan to deal with name conflicts where the ‘video.mp4’ already exists?

It’s these kinds of gotchas that really take the time in projects like these