OS X script SOMETIMES wants to launch Classic.

Scripting Forums AppleScript | Mac OS X
,
#1

Hello
I have this script running on 12 G5:s under 10.4.10, and I THINK that it is the script that sometimes on random machines wants to launch Classic, getting this message: “Classic cannot find a Mac OS 9 system folder on the startup disk to use…”

We do not have classic installed on our machines, so I would like to solve this problem, can any of you script aces out there see if there is anything “Classic-looking” in this script?

(It works fine except from this random glitch)

tell application "System Events" to set this_user to (name of current user)
tell application "Finder"
	
	set UtskjutningsMApp to folder "MALLOBJEKT" of folder "AUTO_MALLAR" of folder "_TEKNIK_" of disk "Server" as alias
	set LokalMallMapp to folder this_user of folder "Users" of disk "Systemdisk" as alias
	set the ShootOut_folder to folder "UTKOPIERAT_TILL" of folder "AUTO_MALLAR" of folder "_TEKNIK_" of disk "Server" as alias
	
	set LokalDorisMapp to disk "Systemdisk" as alias
	
	if not (exists folder this_user of the ShootOut_folder) then
		try
			
			tell application "Finder" to duplicate UtskjutningsMApp to LokalMallMapp replacing yes
			
		on error e
			display dialog "Something is wrong" buttons "Cancel" default button "Cancel"
			
			
		end try
		
		
		try
			make new folder at the ShootOut_folder with properties {name:{this_user} as string}
		on error
			display dialog "The folder " & (this_user as string) & " could not be created." buttons "Avbryt" default button "Avbryt"
		end try
		
	end if
end tell

Regards / Johan

#2

Hi Johan,

if the disk “Server” is a network volume, I recommend to use file specifiers instead of an alias.
Assuming “Systemdisk” is the start volume thy this

property UtskjutningsMApp : "Server:_TEKNIK_:AUTO_MALLAR:MALLOBJEKT:"
property ShootOut_folder : "Server:_TEKNIK_:AUTO_MALLAR:UTKOPIERAT_TIL:"

set {boot volume:LokalDorisMapp, short user name:this_user} to system info
set LokalMallMapp to path to home folder -- returns the path to home folder of the current user (is of class alias)
tell application "Finder"
	if not (exists folder this_user of folder ShootOut_folder) then
		try
			duplicate folder UtskjutningsMApp to LokalMallMapp replacing yes
		on error e
			display dialog "Something is wrong" buttons "Cancel" default button "Cancel"
		end try
		try
			make new folder at folder ShootOut_folder with properties {name:this_user}
		on error
			display dialog "The folder " & this_user & " could not be created." buttons "Avbryt" default button "Avbryt"
		end try
	end if
end tell
#3

This forum is the best!
(Have not tried it yet, but thanks Stefan) Not that I understand the difference, but your assumptions is right and I will try this!

regards / Johan

#4

And it works!!!

Thanks again Stefan, this forum rocks!

:cool::cool::cool::cool: