Quark Annotate script problem in Leopard

Scripting Forums AppleScript | Mac OS X
,
#1

What is wrong with the following line in Leopard?

							make text box at beginning with properties {bounds:{y1, x1, y2, x2} ¬
								, color:"yellow", name:"annotate" & i, runaround:none runaround}

That line is part of the following script that works in Mac 10.4

tell application "QuarkXPress Passport"
	activate
	if (document 1 exists) then
		tell document 1
			try
				delete (every text box whose name contains "annotate")
			end try
			set {hm, vm} to {horizontal measure, vertical measure}
			if hm is not points or vm is not points then
				set properties to {horizontal measure:points, vertical measure:points}
			end if
			set selection to null
			set view scale to fit page in window
			set AppleScript's text item delimiters to ":"
			repeat with p from 1 to count of pages
				show page p
				tell page p
					repeat with i from 1 to count of picture boxes
						set filePath to (file path of image 1 of picture box i) as Unicode text
						if filePath is not "null" and filePath is not "no disk file" then
							set filename to text item -1 of filePath
							tell picture box i
								set {sc1, sc2} to scale of image 1 as list
								set {y1, x1} to origin of bounds as list
							end tell
							set y2 to ((y1 as real) + 14)
							set x2 to ((x1 as real) + 185)
							make text box at beginning with properties {bounds:{y1, x1, y2, x2} ¬
								, color:"yellow", name:"annotate" & i, runaround:none runaround}
							tell story 1 of text box ("annotate" & i)
								set properties to {font:"Monaco", size:11}
								set contents to ("" & filename & "  " & (sc1 as text))
							end tell
						end if
					end repeat
				end tell
			end repeat
			set AppleScript's text item delimiters to {""}
			if hm is not points or vm is not points then
				set properties to {horizontal measure:hm, vertical measure:vm}
			end if
		end tell
		display dialog "Done." buttons "OK" default button 1 with icon 1 giving up after 1
	else
		display dialog "Open a document, please." buttons "OK" default button 1 with icon 2
	end if
end tell

What am I missing? Thanks in advance.

–Herbert Ripka
Greendale, WI

#2

It seems that the color property can cause problems in Leopard…

http://macscripter.net/viewtopic.php?id=27562

#3

Thank you very much. That idea worked.

The finished script:

tell application "QuarkXPress Passport"
	activate
	if (document 1 exists) then
		tell document 1
			try
				delete (every text box whose name contains "annotate")
			end try
			set {hm, vm} to {horizontal measure, vertical measure}
			if hm is not points or vm is not points then
				set properties to {horizontal measure:points, vertical measure:points}
			end if
			set selection to null
			set view scale to fit page in window
			set AppleScript's text item delimiters to ":"
			set yellowcolor to a reference to name of color spec "Yellow"
			repeat with p from 1 to count of pages
				show page p
				tell page p
					repeat with i from 1 to count of picture boxes
						set filePath to (file path of image 1 of picture box i) as Unicode text
						if filePath is not "null" and filePath is not "no disk file" then
							set fileName to text item -1 of filePath
							tell picture box i
								set {sc1, sc2} to scale of image 1 as list
								set {y1, x1} to origin of bounds as list
							end tell
							set y2 to ((y1 as real) + 14)
							set x2 to ((x1 as real) + 185)
							make text box at beginning with properties {bounds:{y1, x1, y2, x2}, name:"annotate" & i, runaround:none runaround}
							set color of text box 1 to yellowcolor
							tell story 1 of text box ("annotate" & i)
								set properties to {font:"Monaco", size:11}
								set contents to ("" & fileName & "  " & (sc1 as string))
							end tell
						end if
					end repeat
				end tell
			end repeat
			set AppleScript's text item delimiters to {""}
			if hm is not points or vm is not points then
				set properties to {horizontal measure:hm, vertical measure:vm}
			end if
		end tell
		display dialog "Done." buttons "OK" default button 1 with icon 1 giving up after 1
	else
		display dialog "Open a document, please." buttons "OK" default button 1 with icon 2
	end if
end tell