SKProgressBar 1.0, a fully scriptable progress bar

StefanK · June 29, 2011, 9:06pm

Actually this is a topic for ScriptBuilders, but unfortunately ScriptBuilders is still broken.

Inspired by Bruce Phillips’ BP Progress Bar (Thanks Bruce) I wrote a fully scriptable Cocoa application for the same purpose to be able to display a progress bar from plain AppleScript

You can download it here: SKProgressBar 1.0,
it runs on an Intel Mac with 10.5 or higher

This code is also included in the .dmg


(*
	SKProgressBar is a simple but fully scriptable Cocoa application
	including a progress bar, two status text fields (header and footer)
	and an image view to display an icon.
	
	This sample script covers all commands and properties 
	
	Read the AppleScript dictionary for further information
	
	The application can be used faceless by setting the key LSUIElement to 1 in info.plist
	
	System Requirements: Intel Mac with Mac OS 10.5 or higher
	
	Inspired by Bruce Phillips' BP Progress Bar on macscripter.net
	
	SKProgressBar is free for non-commercial use, 
	see the License Agreement in the README file or the About window.

	© 2011 Stefan Klieme
*)

set iconPath to (path to applications folder as text) & "iTunes.app:Contents:Resources:iTunes.icns"

tell application "SKProgressBar"
	activate
	
	-- main window properties
	set floating to false --> default is true
	set position to {100, 100} --> default is {1000, 750}, origin point is bottom left
	set width to 600.0 --> default is 500.0
	set title to "myGreatTitle" --> default is "SKProgressBar"
	
	-- header / footer properties
	set header to "header" --> default is empty string
	set header alignment to right --> default is left
	set footer to "footer" --> default is empty string
	set footer alignment to center -->  default is left
	
	-- image path can be HFS or POSIX path, default is missing value (no image)
	set image path to iconPath
	
	tell progress bar
		set minimum value to 0.0 --> default is 0.0
		set maximum value to 100.0 -->  default is 100.0
		set current value to 30.0 --> default is 0.0
	end tell
	
	set show window to true --> default is false
	tell progress bar
		set indeterminate to false --> default is true
		
		start animation
		repeat 6 times
			increment by 10.0
			delay 1
		end repeat
		stop animation
		
	end tell
	quit
end tell

lemuralex13 · July 6, 2011, 4:49am

Nice, I’ve been looking for one for a while

lemuralex13 · July 6, 2011, 5:18am

BTW, do you know how I could change the footer/header while the animation is playing? Thanks

StefanK · July 6, 2011, 6:58am

Just set it, the animation works asynchronously

lemuralex13 · July 6, 2011, 2:32pm

Ok, I accidently had it all in a progress bar tell, nvm, its good, thanks

thewaytoapplescript · August 12, 2011, 3:49pm

StefanK,

Nice work! Everything works great on Lion, except for one thing…

When the header and footer alinements are set to center, they actually go to the far right. When they are set to right, they are in the center.

Just wanted to let you know!

StefanK · February 13, 2013, 9:28pm

Update: Version 1.0.1

Release Notes:

¢ center / right alignment bug fixed
¢ code signed

Download: SKProgressBar 1.0.1

Adam_Bell · February 14, 2013, 12:29am

For me in OS X 10.8.2, the script hangs with the new version.


tell progress bar
		set indeterminate to false --> default is true
		
		«event PrBrStMn»
		repeat 6 times
			«event PrBrIcRm» given «class bYVl»:10.0
			delay 1
		end repeat
		«event PrBrSpMn»
		
	end tell

StefanK · February 14, 2013, 5:58am

the cryptic raw events should compile as

start animation
increment by
stop animation

Of course I tested the application. It works fine on my machine (also 10.8.2).
Have you deleted the 1.0 version?

flex20 · February 14, 2013, 10:22am

Hi Stefan,
I can confirm Adam’s post about the new version. It hangs on or after “set indeterminate to false” by inserting this in the script:

	tell progress bar
		activate
		set indeterminate to false
		«event PrBrStMn» ”> this
		tell current application
			-- do shell script ...
		end tell
		repeat 10 times
			«event PrBrIcRm» given «class bYVl»:10.0 ”> this
			delay 1
		end repeat
		«event PrBrSpMn» ”> this
	end tell

and these are the script replies:

tell application "SKProgressBar"
	set image path to "path:to:me:Contents:Resources:my.icns"
	set minimum value of progress bar to 0.0
	set maximum value of progress bar to 100.0
	set current value of progress bar to 0.0
	set show window to true
	activate
	set indeterminate of progress bar to false
	«event PrBrStMn» progress bar
		--> error number -1708
Result:
error "SKProgressBar got an error: progress bar doesn't understand the «event PrBrStMn» message." number -1708 from progress bar

I too have 10.8.2 and I deleted all copies of the v1.0 of SKProgressBar.app, except the Time Machine.

Nigel_Garvey · February 14, 2013, 10:57am

For me, in Snow Leopard, the script compiled correctly but, when run, hung for several seconds until the system’s “application downloaded from the Internet” warning appeared. Since that was OK’d, everything seems to work fine.

PS. If I substitute Adam’s and flex20’s raw codes for the keywords, they don’t compile as keywords in the AppleScript Editor window and the script suffers the same problems when run. Maybe there are terminology clashes on Adam’s and flex20’s systems causing miscompilations?

PPS. If I save the correctly compiled script, close AppleScript Editor, zap SKProgressBar from my startup disk, and reopen the script in AppleScript Editor, the raw codes are different from those reported by Adam and flex20:

	tell «class cRpB»
		set «class iDtM» to false --> default is true
		
		«event pGbRStMn»
		repeat 6 times
			«event pGbRIcRm» given «class bYVl»:10.0
			delay 1
		end repeat
		«event pGbRSpMn»
		
	end tell

PPPS. What’s the betting Script Debugger’s involved somehow?

Shane_Stanley · February 14, 2013, 12:21pm

The problem seems to be that Stefan has changed the four-letter codes between versions, and flex20 and Adam must have the old version still on their systems.

In particular, increment has changed from PrBrIcRm to pGbRIcRm, start animation from PrBrStMn to pGbRStMn, and stop animation from PrBrSpMn to pGbRSpMn.

I’m not sure why he made the change, but the solution is to remove the previous version, and convince ASE to remove it from its cache.

flex20 · February 14, 2013, 2:31pm

Hi Shane,
I have actually deleted what I think were all traces of v1.0, except for whatever is in the Time Machine. But just to make sure after your post, I booted on my clean volume I maintain for just such testing.

Then, I ejected my main volume, as well as a scrap volume I have, to make sure that nothing can be accessed on them.

Finally I run my script bundle with the SKProgressBar v1.0.1 in it. It crashed at the same place with the same message.
So, I really don’t think that the cause of the crash has anything to do with a clash of versions.

I also want to point out that I have now two scripts with integrated SKProgressBar v1.0 (I only discovered this app a few days ago) and they work perfectly on my 2010 iMac with 10.8.2.

Cheers, Chris

StefanK · February 14, 2013, 4:57pm

Sorry about the confusion.

I really can’t remember why I changed the four-character codes.
There were some inactive NSScriptCommand classes in the project, so I guess
I changed the respective commands from verb-first to object-first (Shane you know what I mean )
To be consistent the first 4-character codes have been changed to the parent class.

flex20 · February 14, 2013, 7:48pm

Hi Stefan,
Will you now release/post a new version? I checked v1.0.1 you posted at #7 above, but it is still yesterday’s version.
It’s no rush really, because v1.0 is working just fine.
Regards,
Chris

Shane_Stanley · February 14, 2013, 10:05pm

If the message contains “PrBrStMn”, then it’s using the old terminology. It may be just ASE caching it (this is another good reason to use Script Debugger). But whatever, the only place PrBrStMn is used is in the old version.

Try copying the code in Nigel’s message and see what it compiles to.

Shane_Stanley · February 14, 2013, 10:07pm

Ah, I was wondering why you did it

Nigel_Garvey · February 14, 2013, 10:54pm

Did you recompile the script against the new version, making sure the source code in your editor contained all the original keywords?

flex20 · February 15, 2013, 10:01am

OK, this is what I just did again:

restored my clean test volume from a “virgin” 10.8.2 disk image with my basic configuration and disabled Spotlight;
restarted from it and then ejected my main volume to isolate the clean test volume;
opened a new blank script and copy/pasted the code from my original script and then saved the new script as a bundle with a new name;
navigated to it’s Resources folder and copied the SKProgressBar.app v1.0.1 to it;
compiled and saved it; (no app v1.0 or a script containing it, were in sight or ever run on that clean volume)
run it.
It crashed again at the same place, with the same raw codes but, slightly changed script replies:

tell application "SKProgressBar"
	tell progress bar
		activate
		set indeterminate to false
		«event PrBrStMn»
		tell current application
			-- do shell script ...
		end tell
		repeat 10 times
			«event PrBrIcRm» given «class bYVl»:10.0
			delay 1
		end repeat
		«event PrBrSpMn»
	end tell
	quit --> error number 0
end tell
(*Replies
tell application "SKProgressBar"
	activate
	set indeterminate of progress bar to false
	«event PrBrStMn» progress bar
		--> error number -1708
Result:
error "SKProgressBar got an error: progress bar doesn't understand the «event PrBrStMn» message." number -1708 from progress bar*)

While the script was frozen and SKProgressBar was still running, I checked that its version was indeed 1.0.1.
So, I think that shows that v1.0.1 in a clean script, running on a clean volume is still crashing with a reproducible error.

Cheers, Chris

StefanK · February 15, 2013, 10:04am

please replace

«event PrBrStMn» with start animation
«event PrBrIcRm» given «class bYVl»:10.0 with increment by 10
«event PrBrSpMn» with stop animation